
theorem Th8:
  for A being Algebra, A1,A2 being Subalgebra of A holds
  the carrier of A1 c= the carrier of A2 implies A1 is Subalgebra of A2
proof
  let A be Algebra, A1,A2 be Subalgebra of A;
  assume
A1: the carrier of A1 c= the carrier of A2;
  set CA1 = the carrier of A1;
  set CA2 = the carrier of A2;
  set AA = the addF of A;
  set mA = the multF of A;
  set MA = the Mult of A;
A2:0.A1 = 0.A & 0.A2 = 0.A & 1.A1 = 1.A & 1.A2 = 1.A by C0SP1:def 9;
A3:the addF of A1 = (the addF of A2)||the carrier of A1
  proof
    the addF of A1 = AA||CA1 & the addF of A2 = AA||CA2 &
    [:CA1,CA1:] c= [:CA2,CA2:] by A1,C0SP1:def 9,ZFMISC_1:96;
    hence thesis by FUNCT_1:51;
  end;
A4:the multF of A1 = (the multF of A2)||the carrier of A1
  proof
    the multF of A1 = mA||CA1 & the multF of A2 = mA||CA2 &
    [:CA1,CA1:] c= [:CA2,CA2:] by A1,C0SP1:def 9,ZFMISC_1:96;
    hence thesis by FUNCT_1:51;
  end;
  the Mult of A1 = (the Mult of A2) | [:REAL,CA1:]
  proof
    the Mult of A1 = MA|[:REAL,CA1:] & the Mult of A2 = MA|[:REAL,CA2:] &
    [:REAL,CA1:] c= [:REAL,CA2:] by A1,C0SP1:def 9,ZFMISC_1:96;
    hence thesis by FUNCT_1:51;
  end;
  hence thesis by A1,A2,A3,A4,C0SP1:def 9;
end;
