reserve X,Y,Z,x,y,y1,y2 for set,
  D for non empty set,
  k,n,n1,n2,m2,m1 for Nat,

  L,K,M,N for Cardinal,
  f,g for Function;
reserve r for Real;

theorem Th8:
  1-tuples_on D,D are_equipotent & card (1-tuples_on D) = card D
proof
  deffunc f(object) = <*$1*>;
  consider f such that
A1: dom f = D &
for x being object st x in D holds f.x = f(x) from FUNCT_1:sch 3;
  D,1-tuples_on D are_equipotent
  proof
    take f;
    thus f is one-to-one
    proof
      let x,y be object;
      assume x in dom f & y in dom f;
      then
A2:   f.x = <*x*> & f.y = <*y*> by A1;
      <*x*>.1 = x;
      hence thesis by A2,FINSEQ_1:def 8;
    end;
    thus dom f = D by A1;
    thus rng f c= 1-tuples_on D
    proof
      let x be object;
      assume x in rng f;
      then consider y being object such that
A3:   y in dom f and
A4:   x = f.y by FUNCT_1:def 3;
      reconsider y as Element of D by A1,A3;
      x = <*y*> by A1,A4;
      then x in the set of all  <*d*> where d is Element of D ;
      hence thesis by FINSEQ_2:96;
    end;
    let x be object;
    assume x in 1-tuples_on D;
    then reconsider y = x as Element of 1-tuples_on D;
    consider z being Element of D such that
A5: y = <*z*> by FINSEQ_2:97;
    x = f.z by A1,A5;
    hence thesis by A1,FUNCT_1:def 3;
  end;
  hence thesis by CARD_1:5;
end;
