reserve X for Complex_Banach_Algebra,
  w,z,z1,z2 for Element of X,
  k,l,m,n,n1, n2 for Nat,
  seq,seq1,seq2,s,s9 for sequence of X,
  rseq for Real_Sequence;

theorem Th8:
  s is convergent & s9 is convergent implies lim(s*s9)=(lim s)*(lim s9)
proof
  assume that
A1: s is convergent and
A2: s9 is convergent;
  ||.s.|| is bounded by A1,CLVECT_1:117,SEQ_2:13;
  then consider R be Real such that
A3: for n holds ||.s.||.n < R by SEQ_2:def 3;
  set g2=lim s9;
  set g1=lim s;
  set g=g1*g2;
A4: now
    let n;
    ||.s.n.||= ||.s.||.n by NORMSP_0:def 4;
    hence ||.s.n.|| < R by A3;
  end;
  ||. s.1 .|| = ||. s .||.1 by NORMSP_0:def 4;
  then 0<= ||.s.||.1 by CLVECT_1:105;
  then
A5: 0 < R by A3;
  reconsider R as Real;
A6: 0+0<||.g2.||+R by A5,CLVECT_1:105,XREAL_1:8;
A7: 0<=||.g2.|| by CLVECT_1:105;
A8: now
    let p be Real;
    assume
A9: 0<p;
    then consider n1 such that
A10: for m st n1<=m holds ||.s.m-g1.||<p/(||.g2.||+R) by A1,A6,CLVECT_1:def 16;
    consider n2 such that
A11: for m st n2<=m holds ||.s9.m-g2.||<p/(||.g2.||+R) by A2,A6,A9,
CLVECT_1:def 16;
    take n=n1+n2;
    let m such that
A12: n<=m;
    n1<=n1+n2 by NAT_1:12;
    then n1<=m by A12,XXREAL_0:2;
    then ||.s.m-g1.||<=p/(||.g2.||+R) by A10;
    then
A13: ||.g2.||*||.s.m-g1.|| <=||.g2.||*(p/(||.g2.||+R)) by A7,XREAL_1:64;
    ||.(s.m-g1)*g2.||<=||.g2.||*||.s.m-g1.|| by CLOPBAN3:38;
    then
A14: ||.(s.m-g1)*g2.||<=||.g2.||*(p/(||.g2.||+R)) by A13,XXREAL_0:2;
A15: 0<=||.s.m.|| by CLVECT_1:105;
    ||.((s*s9).m)-g.|| =||.s.m*s9.m-g1*g2.|| by LOPBAN_3:def 7
      .=||.(s.m*s9.m-s.m*g2)+(s.m*g2-g1*g2).|| by CLOPBAN3:38
      .=||.s.m*(s9.m-g2)+(s.m*g2-g1*g2).|| by CLOPBAN3:38
      .=||.s.m*(s9.m-g2)+(s.m-g1)*g2.|| by CLOPBAN3:38;
    then
A16: ||.((s*s9).m)-g.||<= ||.s.m*(s9.m-g2).||+||.(s.m-g1)*g2.|| by
CLVECT_1:def 13;
A17: ||.s.m*(s9.m-g2).|| <= ||.s.m.||*||.s9.m-g2.|| by CLOPBAN3:38;
    n2<=n by NAT_1:12;
    then n2<=m by A12,XXREAL_0:2;
    then
A18: ||.s9.m-g2.||<p/(||.g2.||+R) by A11;
A19: 0<=||.s9.m-g2.|| by CLVECT_1:105;
    ||.s.m.||<R by A4;
    then ||.s.m.||*||.s9.m-g2.||<R*(p/(||.g2.||+R)) by A15,A19,A18,XREAL_1:96;
    then
A20: ||.s.m*(s9.m-g2).||<R*(p/(||.g2.||+R)) by A17,XXREAL_0:2;
    R*(p/(||.g2.||+R))+||.g2.||*(p/(||.g2.||+R)) =(p/(||.g2.||+R))*(||.g2
    .||+R)
      .=p by A6,XCMPLX_1:87;
    then ||.s.m*(s9.m-g2).||+||.(s.m-g1)*g2.||<p by A20,A14,XREAL_1:8;
    hence ||.((s*s9).m)-g.||<p by A16,XXREAL_0:2;
  end;
  s*s9 is convergent by A1,A2,Th3;
  hence thesis by A8,CLVECT_1:def 16;
end;
