
theorem Th8:
  for X being non empty set st for a,b being set st a in X & b in X
  ex c being set st c c= a /\ b & c in X holds X is c=filtered
proof
  let X be non empty set such that
A1: for a,b being set st a in X & b in X ex c being set st c c= a /\ b &
  c in X;
  set a = the Element of X;
  defpred P[set] means ex a being set st (for y being set st y in $1 holds a
  c= y) & a in X;
  let Y be finite Subset of X;
A2: now
    let x,B be set;
    assume that
A3: x in Y and
    B c= Y;
    assume P[B];
    then consider a being set such that
A4: for y being set st y in B holds a c= y and
A5: a in X;
    consider c being set such that
A6: c c= a /\ x and
A7: c in X by A1,A3,A5;
A8: a /\ x c= a & a /\ x c= x by XBOOLE_1:17;
    thus P[B \/ {x}]
    proof
      take c;
      hereby
        let y be set;
        assume y in B \/ {x};
        then y in B or y in {x} by XBOOLE_0:def 3;
        then a c= y & c c= a or y = x & c c= x by A4,A6,A8,TARSKI:def 1;
        hence c c= y;
      end;
      thus thesis by A7;
    end;
  end;
  for y being set st y in {} holds a c= y;
  then
A9: P[ {}];
A10: Y is finite;
  thus P[Y] from FINSET_1:sch 2(A10,A9,A2);
end;
