reserve i, j, m, n for Nat,
  z, B0 for set,
  f, x0 for real-valued FinSequence;

theorem Th7:
  for h being natural-valued FinSequence st h is increasing holds
  for i being Nat st i<=len h & 1<=h.1 holds i <= h.i
proof
  let h be natural-valued FinSequence;
  assume
A1: h is increasing;
  defpred P[Nat] means $1<=len h implies $1 <= h.$1;
  let i be Nat;
  assume that
A2: i<=len h and
A3: 1<=h.1;
A4: for k being Nat st P[k] holds P[k+1]
  proof
    let k be Nat;
    assume
A5: P[k];
    k+1<=len h implies k+1 <= h.(k+1)
    proof
A6:   k<k+1 by XREAL_1:29;
      assume
A7:   k+1<=len h;
      then
A8:   k<len h by A6,XXREAL_0:2;
      per cases;
      suppose
        k=0;
        hence k+1<=h.(k+1) by A3;
      end;
      suppose
        k>0;
        then 0+1<=k by NAT_1:13;
        then h.k < h.(k+1) by A1,A8;
        then k<h.(k+1) by A5,A7,A6,XXREAL_0:2;
        hence k+1<=h.(k+1) by NAT_1:13;
      end;
    end;
    hence P[k+1];
  end;
A9: P[0];
  for k being Nat holds P[k] from NAT_1:sch 2(A9,A4);
  hence i<=h.i by A2;
end;
