reserve MS for OrtAfPl;
reserve MP for OrtAfSp;

theorem Th8:
  MS is Euclidean iff MS is satisfying_3H
proof
A1: now
    assume
A2: MS is satisfying_3H;
    now
      let a,b,c,d be Element of MS such that
A3:   a,b _|_ c,d and
A4:   b,c _|_ a,d;
A5:   now
A6:     d,a _|_ c,b & d,c _|_ a,b by A3,A4,ANALMETR:61;
        assume
A7:     not LIN a,b,c;
        then consider d1 being Element of MS such that
A8:     d1,a _|_ b,c and
A9:     d1,b _|_ a,c & d1,c _|_ a,b by A2,CONAFFM:def 3;
A10:    not LIN a,c,b by A7,Th4;
        d1,a _|_ c,b by A8,ANALMETR:61;
        then d,b _|_ a,c by A9,A6,A10,Th6;
        hence b,d _|_ a,c by ANALMETR:61;
      end;
      now
A11:    a=c implies b,d _|_ a,c by ANALMETR:58;
A12:    b=c implies b,d _|_ a,c by A3,ANALMETR:61;
        assume
A13:    LIN a,b,c;
        a=b implies b,d _|_ a,c by A4,ANALMETR:61;
        hence b,d _|_ a,c by A3,A4,A13,A11,A12,Th7;
      end;
      hence b,d _|_ a,c by A5;
    end;
    hence MS is Euclidean;
  end;
  now
    assume
A14: MS is Euclidean;
    now
      let a,b,c be Element of MS;
      assume not LIN a,b,c;
      then consider d being Element of MS such that
A15:  d,a _|_ b,c & d,b _|_ a,c by Th5;
      take d;
      b,c _|_ a,d & c,a _|_ b,d by A15,ANALMETR:61;
      then c,d _|_ b,a by A14;
      hence d,a _|_ b,c & d,b _|_ a,c & d,c _|_ a,b by A15,ANALMETR:61;
    end;
    hence MS is satisfying_3H by CONAFFM:def 3;
  end;
  hence thesis by A1;
end;
