reserve h,h1,h2 for 0-convergent non-zero Real_Sequence,
  c,c1 for constant Real_Sequence,
  f,f1,f2 for PartFunc of REAL,REAL,
  x0,r,r0,r1,r2,g,g1,g2 for Real,
  n0,k,n,m for Element of NAT,
  a,b,d for Real_Sequence,
  x for set;

theorem Th8:
  f is_Rcontinuous_in x0 & f.x0 <> g2 & (ex r st r>0 & [.x0, x0+r.]
c= dom f) implies ex r1 st r1>0 & [.x0, x0+r1.] c= dom f & for g st g in [.x0,
  x0+r1.] holds f.g <> g2
proof
  assume that
A1: f is_Rcontinuous_in x0 and
A2: f.x0 <> g2;
  given r such that
A3: r>0 and
A4: [.x0, x0+r.] c= dom f;
  defpred P[Element of NAT,set] means $2 in [.x0, x0+r/($1+1).] & $2 in dom f
  & f.$2 = g2;
  assume
A5: for r1 st r1>0 & [.x0, x0+r1.] c= dom f ex g st g in [.x0, x0+r1.] &
  f.g = g2;
A6: for n ex g be Element of REAL st P[n,g]
  proof
    let n;
    x0 + 0 <= x0 +r by A3,XREAL_1:7;
    then
A7: x0 in [.x0, x0 + r.] by XXREAL_1:1;
    0 + 1 <= n + 1 by XREAL_1:7;
    then r/(n+1) <= r/1 by A3,XREAL_1:118;
    then
A8: x0 + r/(n+1) <= x0 + r by XREAL_1:7;
    x0 + 0 =x0;
    then x0 <= x0 + r/(n+1) by A3,XREAL_1:7;
    then x0 + r/(n+1) in {g1:x0 <= g1 & g1 <= x0+r} by A8;
    then x0 +r/(n+1) in [.x0,x0+r.] by RCOMP_1:def 1;
    then [.x0,x0+r/(n+1).] c= [.x0,x0+r.] by A7,XXREAL_2:def 12;
    then
A9: [.x0,x0+r/(n+1).] c= dom f by A4;
    then consider g such that
A10: g in [.x0,x0+r/(n+1).] & f.g = g2 by A3,A5,XREAL_1:139;
    take g;
    thus thesis by A9,A10;
  end;
  consider a such that
A11: for n holds P[n,a.n] from FUNCT_2:sch 3(A6);
A12: rng a c= right_open_halfline(x0) /\ dom f
  proof
    let x be object;
    assume x in rng a;
    then consider n such that
A13: x = a.n by FUNCT_2:113;
    a.n in [.x0, x0 + r/(n+1).] by A11;
    then a.n in{g1: x0<=g1 & g1<=x0+ r/(n+1)} by RCOMP_1:def 1;
    then
A14: ex g1 st g1=a.n & x0<=g1 & g1<=x0+ r/(n+1);
    x0 <> a.n by A2,A11;
    then x0 < a.n by A14,XXREAL_0:1;
    then a.n in {g1:x0 <g1};
    then
A15: a.n in right_open_halfline(x0)by XXREAL_1:230;
    a.n in dom f by A11;
    hence thesis by A13,A15,XBOOLE_0:def 4;
  end;
A16: right_open_halfline(x0) /\ dom f c= dom f by XBOOLE_1:17;
A17: for n holds (f/*a).n = g2
  proof
    let n;
    thus g2 =f.(a.n) by A11
      .=(f/*a).n by A12,A16,FUNCT_2:108,XBOOLE_1:1;
  end;
  now
    let n be Nat;
    n in NAT by ORDINAL1:def 12;
    then (f/*a).n=g2 by A17;
    hence (f/*a).n=(f/*a).(n+1) by A17;
  end;
  then
A18: lim (f/*a) = (f/*a).0 by SEQ_4:26,VALUED_0:25
    .= g2 by A17;
  deffunc F(Nat) = x0+r/($1+1);
  reconsider xx0 = x0 as Element of REAL by XREAL_0:def 1;
  set b = seq_const x0;
A19: lim b = b.0 by SEQ_4:26
    .=x0 by SEQ_1:57;
  consider d such that
A20: for n being Nat holds d.n = F(n) from SEQ_1:sch 1;
A21: now
    let n be Nat;
A22: n in NAT by ORDINAL1:def 12;
    a.n in [.x0, x0 + r/(n+1).] by A11,A22;
    then a.n in{g1: x0<=g1 & g1<=x0+ r/(n+1)} by RCOMP_1:def 1;
    then ex g1 st g1=a.n & x0<=g1 & g1<=x0+ r/(n+1);
    hence b.n <=a.n & a.n <= d.n by A20,SEQ_1:57;
  end;
  d is convergent & lim d = x0 by A20,FCONT_3:6;
  then a is convergent & lim a = x0 by A19,A21,SEQ_2:19,20;
  hence contradiction by A1,A2,A12,A18;
end;
