
theorem
  for A being Subset of R^1 holds A is open iff
  for x being Real st x in  A
   ex r being Real st r >0 & ].x-r, x+r.[ c= A
proof
  let A be Subset of R^1;
  reconsider A1=A as Subset of RealSpace by TOPMETR:12;
  thus A is open
    implies for x being Real st x in A
     ex r being Real st r >0 & ].x-r, x+r.[ c= A
  proof
    reconsider A1=A as Subset of R^1;
A1: the topology of R^1 = Family_open_set(RealSpace) by TOPMETR:12;
    assume A is open;
    then
A2: A1 in the topology of R^1 by PRE_TOPC:def 2;
    let x be Real;
    reconsider x1=x as Element of REAL by XREAL_0:def 1;
    reconsider x1 as Element of RealSpace by METRIC_1:def 13;
    assume x in A;
    then consider r being Real such that
A3: r>0 and
A4: Ball(x1,r) c= A1 by A2,A1,PCOMPS_1:def 4;
    ].x-r, x+r.[ c=A1 by A4,Th7;
    hence thesis by A3;
  end;
  assume
A5: for x being Real st x in A
    ex r being Real st r >0 & ].x-r, x+r.[ c= A;
  for x being Element of RealSpace st x in A1
   ex r being Real st r>0 & Ball(x,r) c= A1
  proof
    let x be Element of RealSpace;
    reconsider x1=x as Real;
    assume x in A1;
    then consider r being Real such that
A6: r >0 and
A7: ].x1-r, x1+r.[ c= A1 by A5;
    Ball(x,r) c= A1 by A7,Th7;
    hence thesis by A6;
  end;
  then
A8: A1 in Family_open_set(RealSpace) by PCOMPS_1:def 4;
  the topology of R^1 = Family_open_set(RealSpace) by TOPMETR:12;
  hence thesis by A8,PRE_TOPC:def 2;
end;
