reserve c,c1,c2,x,y,z,z1,z2 for set;
reserve C1,C2,C3 for non empty set;

theorem Th8:
  for f,g be RMembership_Func of C1,C2 holds converse min(f,g) =
  min(converse f,converse g)
proof
  let f,g be RMembership_Func of C1,C2;
A1: dom min(converse f,converse g) = [:C2,C1:] by FUNCT_2:def 1;
A2: for c being Element of [:C2,C1:] st c in [:C2,C1:] holds (converse min(f
  ,g)).c = min(converse f,converse g).c
  proof
    let c being Element of [:C2,C1:];
    assume c in [:C2,C1:];
    consider y,x being object such that
A3: y in C2 and
A4: x in C1 and
A5: c = [y,x] by ZFMISC_1:def 2;
    reconsider y,x as set by TARSKI:1;
A6: [x,y] in [:C1,C2:] by A3,A4,ZFMISC_1:87;
    (converse min(f,g)).(y,x) = min(f,g).(x,y) by A5,Def1
      .=min(f.(x,y),g.(x,y)) by A6,FUZZY_1:def 3
      .=min((converse f).(y,x), g.(x,y)) by A5,Def1
      .=min((converse f).(y,x),(converse g).(y,x)) by A5,Def1;
    hence thesis by A5,FUZZY_1:def 3;
  end;
  dom converse min(f,g) = [:C2,C1:] by FUNCT_2:def 1;
  hence thesis by A1,A2,PARTFUN1:5;
end;
