reserve f for non constant standard special_circular_sequence,
  i,j,k,i1,i2,j1,j2 for Nat,
  r,s,r1,s1,r2,s2 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board;

theorem Th7:
  for f being FinSequence of TOP-REAL 2 holds Rev Y_axis f = Y_axis Rev f
proof
  let f be FinSequence of TOP-REAL 2;
A1: len Rev Y_axis f = len Y_axis f by FINSEQ_5:def 3
    .= len f by GOBOARD1:def 2
    .= len Rev f by FINSEQ_5:def 3;
  len Y_axis f = len f by GOBOARD1:def 2;
  then
A2: dom Y_axis f = dom f by FINSEQ_3:29;
A3: len f = len Rev f by FINSEQ_5:def 3;
  now
    let k such that
A4: k in dom Rev Y_axis f;
    set l = len f + 1 -' k;
A5: k <= len f by A1,A3,A4,FINSEQ_3:25;
    len f < len f + 1 by NAT_1:13;
    then
A6: l + k = len f + 1 by A5,XREAL_1:235,XXREAL_0:2;
A7: Rev Rev Y_axis f = Y_axis f;
    then
A8: l in dom Y_axis f by A1,A3,A4,A6,FINSEQ_5:59;
    thus (Rev Y_axis f).k = (Rev Y_axis f)/.k by A4,PARTFUN1:def 6
      .= (Y_axis f)/.l by A1,A3,A4,A6,A7,FINSEQ_5:66
      .= (Y_axis f).l by A8,PARTFUN1:def 6
      .= (f/.l)`2 by A8,GOBOARD1:def 2
      .= ((Rev f)/.k)`2 by A1,A2,A3,A4,A6,A7,FINSEQ_5:59,66;
  end;
  hence thesis by A1,GOBOARD1:def 2;
end;
