reserve i,j,k for Nat,
  r,s,r1,r2,s1,s2,sb,tb for Real,
  x for set,
  GX for non empty TopSpace;
reserve GZ for non empty TopSpace;
reserve f for non constant standard special_circular_sequence,
  G for non empty-yielding Matrix of TOP-REAL 2;

theorem Th8:
  for P1,P2 being Subset of TOP-REAL 2 st P1={ |[r,s]| : s <= s1 }
  & P2={ |[r2,s2]| : s2 > s1 } holds P1=P2`
proof
  let P1,P2 be Subset of TOP-REAL 2;
  assume
A1: P1={ |[r,s]| : s <= s1 } & P2={ |[r2,s2]| : s2 > s1 };
A2: P2` c= P1
  proof
    let x be object;
    assume
A3: x in P2`;
    then reconsider p=x as Point of TOP-REAL 2;
A4: p=|[p`1,p`2]| by EUCLID:53;
    x in (the carrier of TOP-REAL 2) \ P2 by A3,SUBSET_1:def 4;
    then not x in P2 by XBOOLE_0:def 5;
    then p`2 <= s1 by A1,A4;
    hence thesis by A1,A4;
  end;
  P1 c= P2`
  proof
    let x be object;
    assume
A5: x in P1;
    then ex r,s st |[r,s]|=x & s <= s1 by A1;
    then for r2,s2 holds not (|[r2,s2]|=x & s2 > s1) by SPPOL_2:1;
    then not x in P2 by A1;
    then x in (the carrier of TOP-REAL 2) \ P2 by A5,XBOOLE_0:def 5;
    hence thesis by SUBSET_1:def 4;
  end;
  hence thesis by A2;
end;
