reserve i,j,n,k,m for Nat,
     a,b,x,y,z for object,
     F,G for FinSequence-yielding FinSequence,
     f,g,p,q for FinSequence,
     X,Y for set,
     D for non empty set;

theorem Th8:
  X misses union Y implies card UNION(Y,{X}) = card Y
proof
  assume
A1: X misses union Y;
  deffunc F(set)=$1\/X;
  consider f be Function such that
A2: dom f=Y & for A be set st A in Y holds f.A = F(A) from FUNCT_1:sch 5;
A3: rng f c= UNION(Y,{X})
  proof
    let y be object;
    assume y in rng f;
    then consider x such that
A4:   x in dom f & f.x =y by FUNCT_1:def 3;
    reconsider x as set by TARSKI:1;
    X in {X} by TARSKI:def 1;
    then F(x) in UNION(Y,{X}) by A2,A4,SETFAM_1:def 4;
    hence thesis by A4,A2;
  end;
  UNION(Y,{X}) c= rng f
  proof
    let xy be object;
    assume xy in UNION(Y,{X});
    then consider y,x be set such that
A5:   y in Y & x in {X} & xy=y\/x by SETFAM_1:def 4;
    x=X by A5,TARSKI:def 1;
    then f.y=xy by A5,A2;
    hence thesis by A2,A5,FUNCT_1:def 3;
  end;
  then
A6: UNION(Y,{X}) = rng f by A3;
  f is one-to-one
  proof
    let x,y such that
A7:   x in dom f & y in dom f & f.x=f.y;
    reconsider x,y as set by TARSKI:1;
A8:   x misses X & y misses X by A1,XBOOLE_1:63,A2,A7,ZFMISC_1:74;
    f.x=F(x) & f.y = F(y) by A7,A2;
    hence thesis by A7,A8,XBOOLE_1:71;
  end;
  hence thesis by CARD_1:5,A2,A6,WELLORD2:def 4;
end;
