reserve r,p,x for Real;
reserve n for Element of NAT;
reserve A for non empty closed_interval Subset of REAL;
reserve Z for open Subset of REAL;

theorem
  A c= Z implies integral((id Z)(#)sin,A) = ((-id Z)(#)cos+sin).(
  upper_bound A)-((-id Z)(#)cos+sin).(lower_bound A)
proof
  assume
A1: A c= Z;
A2: dom (-id Z) = dom id Z by VALUED_1:8;
A3: dom ((-id Z)(#)cos+sin) = dom ((-id Z)(#)cos) /\ REAL by SIN_COS:24
,VALUED_1:def 1
    .= dom ((-id Z)(#)cos) by XBOOLE_1:28
    .= dom (-id Z) /\ REAL by SIN_COS:24,VALUED_1:def 4
    .= dom (-id Z) by XBOOLE_1:28
    .= Z by A2,RELAT_1:45;
  then
A4: (-id Z)(#)cos+sin is_differentiable_on Z by FDIFF_4:46;
A5: for x st x in Z holds ((id Z)(#)sin).x = x*sin.x
  proof
    let x;
    assume
A6: x in Z;
    ((id Z)(#)sin).x = ((id Z).x)*(sin.x) by VALUED_1:5
      .= x*sin.x by A6,FUNCT_1:18;
    hence thesis;
  end;
A7: for x being Element of REAL
  st x in dom (((-id Z)(#)cos+sin)`|Z) holds (((-id Z)(#)cos+sin)`|
  Z).x = ((id Z)(#)sin).x
  proof
    let x be Element of REAL;
    assume x in dom (((-id Z)(#)cos+sin)`|Z);
    then
A8: x in Z by A4,FDIFF_1:def 7;
    then (((-id Z)(#)cos+sin)`|Z).x =x*sin.x by A3,FDIFF_4:46
      .= ((id Z)(#)sin).x by A5,A8;
    hence thesis;
  end;
A9: dom ((id Z)(#)sin) = dom (id Z) /\ REAL by SIN_COS:24,VALUED_1:def 4
    .= dom (id Z) by XBOOLE_1:28
    .= Z by RELAT_1:45;
  then dom (((-id Z)(#)cos+sin)`|Z) = dom ((id Z)(#)sin) by A4,FDIFF_1:def 7;
  then
A10: (((-id Z)(#)cos+sin)`|Z) = (id Z)(#)sin by A7,PARTFUN1:5;
  ((id Z)(#)sin)|A is continuous;
  then
A11: (id Z)(#)sin is_integrable_on A by A1,A9,INTEGRA5:11;
  ((id Z)(#)sin)|A is bounded by A1,A9,INTEGRA5:10;
  hence thesis by A1,A3,A11,A10,FDIFF_4:46,INTEGRA5:13;
end;
