reserve x for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th8:
  for X being non empty TopSpace, f1,f2 being Function of X,R^1 st
  f1 is continuous & f2 is continuous & (for q being Point of X holds f2.q<>0)
holds ex g being Function of X,R^1 st (for p being Point of X,r1,r2 being Real
 st f1.p=r1 & f2.p=r2 holds g.p=sqrt(1+(r1/r2)^2)) & g is continuous
proof
  let X be non empty TopSpace, f1,f2 be Function of X,R^1;
  assume
  f1 is continuous & f2 is continuous & for q being Point of X holds f2.q <>0;
  then consider g2 being Function of X,R^1 such that
A1: for p being Point of X,r1,r2 being Real st f1.p=r1 & f2.p=r2
  holds g2.p=1+(r1/r2)^2 and
A2: g2 is continuous by Th7;
  for q being Point of X ex r being Real st g2.q=r & r>=0
  proof
    let q be Point of X;
    reconsider r1=f1.q,r2=f2.q as Real;
    1+(r1/r2)^2>0 by Lm1;
    hence thesis by A1;
  end;
  then consider g3 being Function of X,R^1 such that
A3: for p being Point of X,r1 being Real st g2.p=r1 holds g3.p=
  sqrt( r1) and
A4: g3 is continuous by A2,Th5;
  for p being Point of X,r1,r2 being Real st f1.p=r1 & f2.p=r2
  holds g3.p=sqrt(1+(r1/r2)^2)
  proof
    let p be Point of X,r1,r2 be Real;
    assume f1.p=r1 & f2.p=r2;
    then g2.p=1+(r1/r2)^2 by A1;
    hence thesis by A3;
  end;
  hence thesis by A4;
end;
