reserve a, b, c, d, r, s for Real,
  n for Element of NAT,
  p, p1, p2 for Point of TOP-REAL 2,
  x, y for Point of TOP-REAL n,
  C for Simple_closed_curve,
  A, B, P for Subset of TOP-REAL 2,
  U, V for Subset of (TOP-REAL 2)|C`,
  D for compact with_the_max_arc Subset of TOP-REAL 2;

theorem Th8:
  p1`1 <= r & r <= p2`1 implies LSeg(p1,p2) meets Vertical_Line(r)
proof
  assume that
A1: p1`1 <= r and
A2: r <= p2`1;
  set a = p1`1, b = p2`1;
  set l = (r-a) / (b-a);
  set k = (1-l)*p1+l*p2;
A3: a-a <= r-a by A1,XREAL_1:9;
A4: r-a <= b-a by A2,XREAL_1:9;
  then l <= 1 by A3,XREAL_1:183;
  then
A5: k in LSeg(p1,p2) by A3,A4;
  per cases;
  suppose a <> b;
    then
A6: b-a <> 0;
    k`1 = (1-l)*a+l*b by TOPREAL9:41
      .= a+l*(b-a)
      .= a+(r-a) by A6,XCMPLX_1:87;
    then k in Vertical_Line(r) by JORDAN6:31;
    hence thesis by A5,XBOOLE_0:3;
  end;
  suppose
A7: a = b;
A8: p1 in LSeg(p1,p2) by RLTOPSP1:68;
    a = r by A1,A2,A7,XXREAL_0:1;
    then p1 in Vertical_Line(r) by JORDAN6:31;
    hence thesis by A8,XBOOLE_0:3;
  end;
end;
