reserve x,x1,x2,y,z,z1 for set;
reserve s1,r,r1,r2 for Real;
reserve s,w1,w2 for Real;
reserve n,i for Element of NAT;
reserve X for non empty TopSpace;
reserve p,p1,p2,p3 for Point of TOP-REAL n;
reserve P for Subset of TOP-REAL n;

theorem Th8:
  (0*n)/^i=0*(n-'i)
proof
A1: len ((0*n)/^i) = len (0*n)-'i by RFINSEQ:29
    .=n-'i by CARD_1:def 7;
A2: n=len (0*n) by CARD_1:def 7;
A3: for j be Nat st 1<=j & j<=n-'i holds ((0*n)/^i).j=(0*(n-'i)).j
  proof
    let j be Nat;
    assume that
A4: 1<=j and
A5: j<=n-'i;
    now
      assume n<i;
      then n-i<i-i by XREAL_1:9;
      hence contradiction by A4,A5,XREAL_0:def 2;
    end;
    then n-'i=n-i by XREAL_1:233;
    then
A6: j+i<=n-i+i by A5,XREAL_1:6;
    1<=j+i by A4,NAT_1:12;
    then
A7: j+i in Seg n by A6,FINSEQ_1:1;
A8: j in Seg (n-'i) by A4,A5,FINSEQ_1:1;
    then
A9: j in dom ((0*n)/^i) by A1,FINSEQ_1:def 3;
    now
      per cases;
      case
        i<=len (0*n);
        hence ((0*n)/^i).j=(n |-> (0 qua Real)).(j+i) by A9,RFINSEQ:def 1
          .=0 by A7,FUNCOP_1:7
          .= (0*(n-'i)).j by A8,FUNCOP_1:7;
      end;
      case
A10:    i>len (0*n);
        then i-i>n-i by A2,XREAL_1:9;
        then
A11:    n-'i=0 by XREAL_0:def 2;
        ((0*n)/^i).j = (<*>REAL).j by A10,RFINSEQ:def 1;
        hence thesis by A11;
      end;
    end;
    hence thesis;
  end;
  n-'i=len (0*(n-'i)) by CARD_1:def 7;
  hence thesis by A1,A3,FINSEQ_1:14;
end;
