reserve x,y for object,
  N for Element of NAT,
  c,i,j,k,m,n for Nat,
  D for non empty set,
  s for Element of 2Set Seg (n+2),
  p for Element of Permutations(n) ,
  p1, q1 for Element of Permutations(n+1),
  p2 for Element of Permutations(n +2),
  K for Field,
  a for Element of K,
  f for FinSequence of K,
  A for (Matrix of K),
  AD for Matrix of n,m,D,
  pD for FinSequence of D,
  M for Matrix of n,K;

theorem Th8:
  for K be Fanoian Field for p2 for X,Y be Element of Fin 2Set Seg
  (n+2) st Y={s:s in X & Part_sgn(p2,K).s = -1_K} holds (the multF of K) $$ (X,
  Part_sgn(p2,K)) = power(K).(-1_K,card Y)
proof
  let K be Fanoian Field;
  let p2;
  set n2=n+2;
  let X,Y be Element of Fin 2Set Seg n2 such that
A1: Y={s:s in X & Part_sgn(p2,K).s = -1_K};
  reconsider ID = id Seg n2 as Element of Permutations(n2) by MATRIX_1:def 12;
  set Y9= {s:s in X & Part_sgn(p2,K).s <> Part_sgn(ID,K).s};
A2: for x st x in X holds Part_sgn(ID,K).x = 1_K
  proof
A3: X c= 2Set Seg n2 by FINSUB_1:def 5;
    let x;
    assume x in X;
    then consider i,j be Nat such that
A4: i in Seg n2 and
A5: j in Seg n2 and
A6: i < j and
A7: x = {i,j} by A3,MATRIX11:1;
A8: ID.j=j by A5,FUNCT_1:17;
    ID.i=i by A4,FUNCT_1:17;
    hence thesis by A4,A5,A6,A7,A8,MATRIX11:def 1;
  end;
A9: Y9 c= Y
  proof
    let y be object;
    assume y in Y9;
    then consider s such that
A10: y=s and
A11: s in X and
A12: Part_sgn(p2,K).s <> Part_sgn(ID,K).s;
    Part_sgn(ID,K).s=1_K by A2,A11;
    then Part_sgn(p2,K).s =-1_K by A12,MATRIX11:5;
    hence thesis by A1,A10,A11;
  end;
  Y c= Y9
  proof
    let y be object;
A13: 1_K<>-1_K by MATRIX11:22;
    assume y in Y;
    then consider s such that
A14: s=y and
A15: s in X and
A16: Part_sgn(p2,K).s = -1_K by A1;
    Part_sgn(ID,K).s=1_K by A2,A15;
    hence thesis by A14,A15,A16,A13;
  end;
  then
A17: Y=Y9 by A9,XBOOLE_0:def 10;
  per cases by NAT_D:12;
  suppose
A18: card Y mod 2 = 0;
    then consider t be Nat such that
A19: card Y = 2 * t + 0 and
    0 < 2 by NAT_D:def 2;
    t is Element of NAT by ORDINAL1:def 12;
    hence power(K).(-1_K,card Y)=1_K by A19,HURWITZ:4
      .= (the multF of K) $$ (X,Part_sgn(ID,K)) by A2,MATRIX11:4
      .= (the multF of K) $$ (X,Part_sgn(p2,K)) by A17,A18,MATRIX11:7;
  end;
  suppose
A20: card Y mod 2 = 1;
    then consider t be Nat such that
A21: card Y = 2 * t + 1 and
    1 < 2 by NAT_D:def 2;
    t is Element of NAT by ORDINAL1:def 12;
    hence power(K).(-1_K,card Y)=-1_K by A21,HURWITZ:4
      .= -(the multF of K) $$ (X,Part_sgn(ID,K)) by A2,MATRIX11:4
      .= (the multF of K) $$ (X,Part_sgn(p2,K)) by A17,A20,MATRIX11:7;
  end;
end;
