reserve x for set,
  K for Ring,
  r for Scalar of K,
  V for LeftMod of K,
  a,b,a1,a2 for Vector of V,
  A,A1,A2 for Subset of V,
  l for Linear_Combination of A,
  W for Subspace of V,
  Li for FinSequence of Submodules(V);

theorem
  SubMeet(V) is commutative associative & SubMeet(V)
  is having_a_unity & (Omega).V = the_unity_wrt SubMeet(V)
proof
  set S0=Submodules(V), S2=SubMeet(V);
  reconsider L=LattStr(#(S0 qua non empty set),(SubJoin(V) qua BinOp of S0),
    (S2 qua BinOp of S0)#) as Lattice by VECTSP_5:57;
  S2=the L_meet of L;
  hence S2 is commutative associative;
  set e=(Omega).V;
  reconsider e9=@e as Element of (S0 qua non empty set);
A1: e9=e by LMOD_6:def 2;
  now
    let a9 be Element of (S0 qua non empty set);
    reconsider b=a9 as Element of S0;
    reconsider a=b as strict Subspace of V;
    thus (S2 qua BinOp of S0).(e9,a9) = e/\a by A1,VECTSP_5:def 8
      .= a9 by VECTSP_5:21;
    thus (S2 qua BinOp of S0).(a9,e9) = a/\e by A1,VECTSP_5:def 8
      .= a9 by VECTSP_5:21;
  end;
  then
A2: e9 is_a_unity_wrt (S2 qua BinOp of S0) by BINOP_1:3;
  hence S2 is having_a_unity by SETWISEO:def 2;
  thus thesis by A1,A2,BINOP_1:def 8;
end;
