reserve I, G, H for set, i, x for object,
  A, B, M for ManySortedSet of I,
  sf, sg, sh for Subset-Family of I,
  v, w for Subset of I,
  F for ManySortedFunction of I;

theorem :: SETFAM_1:10
  sh = sf \/ sg implies Intersect sh = Intersect sf /\ Intersect sg
proof
  assume
A1: sh = sf \/ sg;
  per cases;
  suppose
    sf = {} & sg = {};
    hence thesis by A1;
  end;
  suppose
A2: sf <> {} & sg = {};
    hence Intersect sh = meet sf by A1,SETFAM_1:def 9
      .= meet sf /\ I by XBOOLE_1:28
      .= Intersect sf /\ I by A2,SETFAM_1:def 9
      .= Intersect sf /\ Intersect sg by A2,SETFAM_1:def 9;
  end;
  suppose
A3: sf = {} & sg <> {};
    hence Intersect sh = meet sg by A1,SETFAM_1:def 9
      .= I /\ meet sg by XBOOLE_1:28
      .= I /\ Intersect sg by A3,SETFAM_1:def 9
      .= Intersect sf /\ Intersect sg by A3,SETFAM_1:def 9;
  end;
  suppose
A4: sf <> {} & sg <> {};
    then
A5: Intersect sg = meet sg by SETFAM_1:def 9;
    Intersect sh = meet sh & Intersect sf = meet sf by A1,A4,SETFAM_1:def 9;
    hence thesis by A1,A4,A5,SETFAM_1:9;
  end;
end;
