
theorem Th8:
  for X being non empty set st 3 c= card X
  for K being Subset of X st card K = 2
  for S being TopStruct st the carrier of S = X & the topology of S
  = {L where L is Subset of X : 2 = card L} \ {K} holds S is non empty non void
non degenerated truly-partial with_non_trivial_blocks identifying_close_blocks
  without_isolated_points
proof
  let X be non empty set;
  assume
A1: 3 c= card X;
  let K be Subset of X;
  assume
A2: card K = 2;
  then reconsider K9=K as finite Subset of X;
  consider x,y being object such that
A3: x <> y and
A4: K9 = {x,y} by A2,CARD_2:60;
  let S be TopStruct;
  assume that
A5: the carrier of S = X and
A6: the topology of S = {L where L is Subset of X : 2 = card L} \ {K};
  reconsider x,y as Point of S by A5,A4,ZFMISC_1:32;
  consider z being object such that
A7: z in X and
A8: z <> x and
A9: z <> y by A1,Th6;
  {x,z} c= X
  proof
    let a be object;
    assume a in {x,z};
    then a=x or a=z by TARSKI:def 2;
    hence thesis by A5,A7;
  end;
  then reconsider l = {x,z} as Subset of X;
  card l = 2 by A8,CARD_2:57;
  then
A10: z in l & l in {L where L is Subset of X : 2 = card L} by TARSKI:def 2;
  thus S is non empty by A5;
  not z in K9 by A4,A8,A9,TARSKI:def 2;
  then
A11: not {L where L is Subset of X : 2 = card L} c= {K} by A10,TARSKI:def 1;
  then
A12: {L where L is Subset of X : 2 = card L} \ {K} is non empty by XBOOLE_1:37;
  hence S is non void by A6;
  reconsider F={L where L is Subset of X : 2 = card L} \ {K} as non empty set
  by A11,XBOOLE_1:37;
  now
    assume X in F;
    then X in {L where L is Subset of X : 2 = card L};
    then ex L being Subset of X st X=L & 2 = card L;
    then Segm 3 c= Segm 2 by A1;
    hence contradiction by NAT_1:39;
  end;
  then not X is Element of F;
  hence S is non degenerated by A5,A6;
  thus S is truly-partial
  proof
    take x,y;
    for l being Block of S holds not {x,y} c= l
    proof
      let l be Block of S;
      l in {L where L is Subset of X : 2 = card L} by A6,A12,XBOOLE_0:def 5;
      then consider L being Subset of X such that
A13:  l = L and
A14:  card L = 2;
      reconsider L9=L as finite Subset of X by A14;
      consider a,b being object such that
      a <> b and
A15:  L9 = {a,b} by A14,CARD_2:60;
A16:  not l in {K} by A6,A12,XBOOLE_0:def 5;
      now
        assume
A17:    {x,y} c= l;
        then y in L9 by A13,ZFMISC_1:32;
        then
A18:    y = a or y = b by A15,TARSKI:def 2;
        x in L9 by A13,A17,ZFMISC_1:32;
        then x = a or x = b by A15,TARSKI:def 2;
        hence contradiction by A3,A4,A16,A13,A15,A18,TARSKI:def 1;
      end;
      hence thesis;
    end;
    hence thesis by A3;
  end;
  thus S is with_non_trivial_blocks
  proof
    let k be Block of S;
    k in {L where L is Subset of X : 2 = card L} by A6,A12,XBOOLE_0:def 5;
    then ex m being Subset of X st m = k & card m = 2;
    hence thesis;
  end;
  thus S is identifying_close_blocks
  proof
    let k,l be Block of S;
    assume 2 c= card(k /\ l);
    then consider a,b being object such that
A19: a in k /\ l & b in k /\ l and
A20: a <> b by Th2;
A21: {a,b} c= k /\ l
    by A19,TARSKI:def 2;
    l in {L where L is Subset of X : 2 = card L} by A6,A12,XBOOLE_0:def 5;
    then
A22: ex n being Subset of X st n = l & card n = 2;
    then reconsider l1=l as finite set;
A23: k /\ l c= l1 by XBOOLE_1:17;
    k in {L where L is Subset of X : 2 = card L} by A6,A12,XBOOLE_0:def 5;
    then
A24: ex m being Subset of X st m = k & card m = 2;
    then reconsider k1=k as finite set;
A25: card {a,b} = 2 by A20,CARD_2:57;
    k /\ l c= k1 by XBOOLE_1:17;
    then {a,b} = k1 by A24,A21,A25,CARD_2:102,XBOOLE_1:1;
    hence thesis by A21,A25,A22,A23,CARD_2:102,XBOOLE_1:1;
  end;
A26: Segm 2 c= Segm 3 by NAT_1:39;
  thus S is without_isolated_points
  proof
    let p be Point of S;
    per cases;
    suppose
A27:  p <> x & p <> y;
      consider z being object such that
A28:  z in X and
A29:  z <> p by A1,A26,Th3,XBOOLE_1:1;
      {p,z} c= X
      proof
        let a be object;
        assume a in {p,z};
        then a=p or a=z by TARSKI:def 2;
        hence thesis by A5,A28;
      end;
      then reconsider el = {p,z} as Subset of X;
      card {p,z} = 2 by A29,CARD_2:57;
      then
A30:  el in {L where L is Subset of X : 2 = card L};
      p in el by TARSKI:def 2;
      then el <> K by A4,A27,TARSKI:def 2;
      then not el in {K} by TARSKI:def 1;
      then reconsider el as Block of S by A6,A30,XBOOLE_0:def 5;
      take el;
      thus thesis by TARSKI:def 2;
    end;
    suppose
A31:  p=x or p=y;
      consider z being object such that
A32:  z in X and
A33:  z <> x & z <> y by A1,Th6;
      {p,z} c= X
      proof
        let a be object;
        assume a in {p,z};
        then a=p or a=z by TARSKI:def 2;
        hence thesis by A5,A32;
      end;
      then reconsider el = {p,z} as Subset of X;
      card {p,z} = 2 by A31,A33,CARD_2:57;
      then
A34:  el in {L where L is Subset of X : 2 = card L};
      z in el by TARSKI:def 2;
      then el <> K by A4,A33,TARSKI:def 2;
      then not el in {K} by TARSKI:def 1;
      then reconsider el as Block of S by A6,A34,XBOOLE_0:def 5;
      take el;
      thus thesis by TARSKI:def 2;
    end;
  end;
end;
