reserve i,j,x,y for object,
  f,g for Function;

theorem
  for n being Nat, a being set holds
    product ( n |-> {a} ) = { n |-> a }
proof
  let n be Nat, a be set;
  now
    let i be object;
    hereby
      assume i in product ( n |-> {a} );
      then consider g being Function such that
A1:   i = g and
A2:   dom g = dom( n |-> {a} ) and
A3:   for x being object st x in dom( n |-> {a} )
holds g.x in ( n |-> {a} ).x by
CARD_3:def 5;
A4:   dom g = Seg n by A2;
      now
        let x be object;
        assume
A5:     x in dom g;
        then g.x in ( n |-> {a} ).x by A2,A3;
        then g.x in {a} by A4,A5,FUNCOP_1:7;
        hence g.x = a by TARSKI:def 1;
      end;
      hence i = n |-> a by A1,A4,FUNCOP_1:11;
    end;
    assume
A6: i = n |-> a;
    then reconsider g = i as Function;
A7: now
      let x be object;
      assume x in dom( n |-> {a} );
      then x in Seg n;
      then g.x = a & ( n |-> {a} ).x = {a} by A6,FUNCOP_1:7;
      hence g.x in ( n |-> {a} ).x by TARSKI:def 1;
    end;
    dom g = Seg n by A6
      .= dom( n |-> {a} );
    hence i in product ( n |-> {a} ) by A7,CARD_3:9;
  end;
  hence thesis by TARSKI:def 1;
end;
