reserve x,y for set,
        r,s for Real,
        n for Nat,
        V for RealLinearSpace,
        v,u,w,p for VECTOR of V,
        A,B for Subset of V,
        Af for finite Subset of V,
        I for affinely-independent Subset of V,
        If for finite affinely-independent Subset of V,
        F for Subset-Family of V,
        L1,L2 for Linear_Combination of V;

theorem Th8:
  conv A = union {Int B : B c= A}
  proof
    defpred P[Nat] means
    for S be finite Subset of V st card S<=$1 holds conv S=union{Int B:B c=S};
    set I={Int B:B c=A};
    A1: for A be Subset of V holds union{Int B:B c=A}c=conv A
    proof
      let A be Subset of V;
      set I={Int B:B c=A};
      let y be object;
      assume y in union I;
      then consider x such that
      A2: y in x and
      A3: x in I by TARSKI:def 4;
      consider B be Subset of V such that
      A4: x=Int B and
      A5: B c=A by A3;
      A6: conv B c=conv A by A5,RLAFFIN1:3;
      y in conv B by A2,A4,Def1;
      hence thesis by A6;
    end;
    A7: for n be Nat st P[n] holds P[n+1]
    proof
      let n be Nat such that
      A8: P[n];
      let S be finite Subset of V such that
      A9: card S<=n+1;
      per cases by A9,NAT_1:8;
      suppose card S<=n;
        hence thesis by A8;
      end;
      suppose A10: card S=n+1;
        set I={Int B:B c=S};
        A11: conv S c=union I
        proof
          let x be object such that
          A12: x in conv S;
          per cases;
          suppose for A be Subset of V st A c<S holds not x in conv A;
            then Int S in I & x in Int S by A12,Def1;
            hence thesis by TARSKI:def 4;
          end;
          suppose ex A be Subset of V st A c<S & x in conv A;
            then consider A be Subset of V such that
            A13: A c<S and
            A14: x in conv A;
            A15: A c=S by A13;
            then reconsider A as finite Subset of V;
            card A<n+1 by A10,A13,CARD_2:48;
            then card A<=n by NAT_1:13;
            then conv A=union{Int B:B c=A} by A8;
            then consider Y be set such that
            A16: x in Y and
            A17: Y in {Int B:B c=A} by A14,TARSKI:def 4;
            consider B be Subset of V such that
            A18: Y=Int B and
            A19: B c=A by A17;
            B c=S by A15,A19;
            then Int B in I;
            hence thesis by A16,A18,TARSKI:def 4;
          end;
        end;
        union I c=conv S by A1;
        hence thesis by A11;
      end;
    end;
    A20: P[0 qua Nat]
    proof
      let A be finite Subset of V;
      set I={Int B:B c=A};
      assume card A<=0;
      then A is empty;
      then A21: conv A is empty;
      union I c=conv A by A1;
      hence thesis by A21;
    end;
    A22: for n be Nat holds P[n] from NAT_1:sch 2(A20,A7);
    hereby let x be object such that
      A23: x in conv A;
      reconsider A1=A as non empty Subset of V by A23;
      conv A={Sum L where L is Convex_Combination of A1:L in ConvexComb(V)}
        by CONVEX3:5;
      then consider L be Convex_Combination of A1 such that
      A24: x=Sum L & L in ConvexComb(V) by A23;
      reconsider C=Carrier L as non empty finite Subset of V by CONVEX1:21;
      reconsider K=L as Linear_Combination of C by RLVECT_2:def 6;
      K is convex;
      then x in {Sum M where M is Convex_Combination of C:M in ConvexComb(V)}
        by A24;
      then A25: x in conv C by CONVEX3:5;
      P[card C] by A22;
      then x in union{Int B:B c=C} by A25;
      then consider y such that
      A26: x in y and
      A27: y in {Int B:B c=C} by TARSKI:def 4;
      consider B be Subset of V such that
      A28: y=Int B and
      A29: B c=C by A27;
      C c=A by RLVECT_2:def 6;
      then B c=A by A29;
      then Int B in I;
      hence x in union I by A26,A28,TARSKI:def 4;
    end;
    thus thesis by A1;
  end;
