 reserve x for set,
         n,m,k for Nat,
         r for Real,
         V for RealLinearSpace,
         v,u,w,t for VECTOR of V,
         Av for finite Subset of V,
         Affv for finite affinely-independent Subset of V;
reserve pn for Point of TOP-REAL n,
        An for Subset of TOP-REAL n,
        Affn for affinely-independent Subset of TOP-REAL n,
        Ak for Subset of TOP-REAL k;

theorem Th8:
  for A be Subset of TOP-REAL(k+n) st
    A = the set of all v^(n|->0) where v is Element of TOP-REAL k
  for B be Subset of (TOP-REAL(k+n))|A st
    B = {v where v is Point of TOP-REAL(k+n): v|k in Ak & v in A}
  holds Ak is open iff B is open
proof
  set kn=k+n;
  set TRn=TOP-REAL kn;
  set TRk=TOP-REAL k;
  let A be Subset of TRn such that
   A1: A=the set of all v^(n|->0) where v is Element of TRk;
  A2: the TopStruct of TRk=TopSpaceMetr Euclid k by EUCLID:def 8;
  then reconsider p=Ak as Subset of TopSpaceMetr Euclid k;
  set TRA=TRn|A;
  let B be Subset of TRn|A such that
   A3: B={v where v is Element of TRn:v|k in Ak & v in A};
  A4: [#]TRA=A by PRE_TOPC:def 5;
  A5: kn>=k by NAT_1:11;
  hereby set PP={v where v is Element of TRn:v|k in Ak};
   PP c=[#]TRn
   proof
    let x be object;
    assume x in PP;
    then ex v be Element of TRn st x=v & v|k in Ak;
    hence thesis;
   end;
   then reconsider PP as Subset of TRn;
   A6: PP/\A c=B
   proof
    let x be object;
    assume A7: x in PP/\A;
    then x in PP by XBOOLE_0:def 4;
    then consider v be Element of TRn such that
     A8: x=v & v|k in Ak;
    x in A by A7,XBOOLE_0:def 4;
    hence thesis by A3,A8;
   end;
   assume Ak is open;
   then PP is open by A5,Th7;
   then PP in the topology of TRn by PRE_TOPC:def 2;
   then A9: PP/\[#]TRA in the topology of TRA by PRE_TOPC:def 4;
   B c=PP/\A
   proof
    let x be object;
    assume x in B;
    then consider v be Element of TRn such that
     A10: x=v and
     A11: v|k in Ak and
     A12: v in A by A3;
    v in PP by A11;
    hence thesis by A10,A12,XBOOLE_0:def 4;
   end;
   then B=PP/\A by A6;
   hence B is open by A4,A9,PRE_TOPC:def 2;
  end;
  assume B is open;
  then B in the topology of TRA by PRE_TOPC:def 2;
  then consider Q be Subset of TRn such that
   A13: Q in the topology of TRn and
   A14: Q/\[#]TRA=B by PRE_TOPC:def 4;
  A15: the TopStruct of TRn=TopSpaceMetr Euclid kn by EUCLID:def 8;
  then reconsider q=Q as Subset of TopSpaceMetr Euclid kn;
  A16: q is open by A13,A15,PRE_TOPC:def 2;
  for e being Point of Euclid k st e in p ex r being Real st r>0 &
    OpenHypercube(e,r)c=p
  proof
   let e be Point of Euclid k;
   A17: len(n|->0)=n by CARD_1:def 7;
   A18: @@(e^(n|->0))=e^(n|->0);
   A19: len e=k by CARD_1:def 7;
   then len(e^(n|->0))=kn by A17,FINSEQ_1:22;
   then reconsider e0=e^(n|->0) as Point of Euclid kn by A18,TOPREAL3:45;
   dom e=Seg k by A19,FINSEQ_1:def 3;
   then A20: e =e0|k by FINSEQ_1:21;
   n|->0=@@(n|->0);
   then reconsider N=n|->0 as Element of Euclid n by A17,TOPREAL3:45;
   e is Element of TRk by Lm1;
   then A21: e0 in A by A1;
   assume e in p;
   then e0 in B by A3,A21,A20;
   then e0 in q by A14,XBOOLE_0:def 4;
   then consider m be non zero Element of NAT such that
    A22: OpenHypercube(e0,1/m)c=q by A16,EUCLID_9:23;
   set r=1/m;
   take r;
   thus r>0 by XREAL_1:139;
   let x be object;
   N in OpenHypercube(N,r) by EUCLID_9:11,XREAL_1:139;
   then A23: N in product Intervals(N,r) by EUCLID_9:def 4;
   assume A24: x in OpenHypercube(e,r);
   then reconsider w=x as Point of TRk by A2;
   A25: Intervals(e,r)^Intervals(N,r)=Intervals(e^N,r) by Th1;
   w in product Intervals(e,r) by A24,EUCLID_9:def 4;
   then w^N in product Intervals(e0,r) by A23,A25,Th2;
   then A26: w^N in OpenHypercube(e0,r) by EUCLID_9:def 4;
   w^N in A by A1;
   then w^N in B by A4,A14,A22,A26,XBOOLE_0:def 4;
   then A27: ex v be Element of TRn st w^N=v & v|k in Ak & v in A by A3;
   len w=k by CARD_1:def 7;
   then (w^N)|k=(w^N)|dom w by FINSEQ_1:def 3
    .=w by FINSEQ_1:21;
   hence thesis by A27;
  end;
  then p is open by EUCLID_9:24;
  then Ak in the topology of TOP-REAL k by A2,PRE_TOPC:def 2;
  hence thesis by PRE_TOPC:def 2;
end;
