 reserve X for set;
 reserve S for Subset-Family of X;

theorem
  for X1,X2 be non empty set, S1 be with_countable_Cover Subset-Family of X1,
  S2 be with_countable_Cover Subset-Family of X2, S be Subset-Family of
  [:X1,X2:] st S= {s where s is Subset of [:X1,X2:]: ex x1,x2 be set st
  x1 in S1 & x2 in S2 & s=[:x1,x2:]} holds S is with_countable_Cover
  proof
    let X1,X2 be non empty set;
    let S1 be with_countable_Cover Subset-Family of X1;
    let S2 be with_countable_Cover Subset-Family of X2;
    let S be Subset-Family of [:X1,X2:];
    assume
A1: S= {s where s is Subset of [:X1,X2:]: ex
    x1,x2 be set st x1 in S1 & x2 in S2 & s=[:x1,x2:]};
    ex U be countable Subset of S st union U = [:X1,X2:] & U is Subset of S
    proof
      consider U1 be countable Subset of S1 such that
A2:   U1 is Cover of X1 by SRINGS_1:def 4;
A3:   union U1 = X1 by A2,Lem6a;
      consider U2 be countable Subset of S2 such that
A4:   U2 is Cover of X2 by SRINGS_1:def 4;
A5:   union U2=X2 by A4,Lem6a;
      set U={u where u is Subset of [:X1,X2:] :ex u1,u2 be set st
      u1 in U1\{{}} & u2 in U2\{{}} & u=[:u1,u2:]};
A6:   U1 is non empty by A2,ZFMISC_1:2,Lem6a;
A7:   U1\{{}} is non empty
      proof
        assume U1\{{}} is empty;
        then union U1 c= union {{}} by ZFMISC_1:77,XBOOLE_1:37;
        hence thesis by A2,Lem6a;
      end;
A8:   U2 is non empty by A4,Lem6a,ZFMISC_1:2;
A9:   U2\{{}} is non empty
      proof
        assume U2\{{}} is empty;
        then union U2 c= union {{}} by ZFMISC_1:77,XBOOLE_1:37;
        hence contradiction by A4,Lem6a;
      end;
      set V={[:a,b:] where a is Element of U1,
      b is Element of U2 :a in U1\{{}} & b in U2\{{}}};
A10:  U=V
      proof
        U1 is Subset-Family of X1 & U2 is Subset-Family of X2 by Lem9;
        hence thesis by A6,A8,Lemme9;
      end;
      U is Subset of S
      proof
        for x be object st x in U holds x in S
        proof
          let x be object;
          assume x in U;
          then consider u0 be Subset of [:X1,X2:] such that
A11:      x=u0 & ex u1,u2 be set st
          u1 in U1\{{}} & u2 in U2\{{}} & u0=[:u1,u2:];
          reconsider x as Subset of [:X1,X2:] by A11;
          thus thesis by A1,A11;
        end;
        hence thesis by TARSKI:def 3;
      end;
      then reconsider U as Subset of S;
A12:  U is countable
      proof
        U1\{{}} is countable & U2\{{}} is countable by CARD_3:95;
        then
A13:    [:U1\{{}},U2\{{}}:] is countable by CARD_4:7;
        set W=[:U1\{{}},U2\{{}}:];
        V, W are_equipotent
        proof
          set Z={[[:u1,u2:],[u1,u2]] where u1 is Element of U1,
          u2 is Element of U2: u1 in U1\{{}} & u2 in U2\{{}}};
A14:      (for v be object st v in V ex w be object st w in W & [v,w] in Z)&
          (for w be object st w in W ex v be object st v in V & [v,w] in Z)&
          for v1,v2,w1,w2 be object st [v1,w1] in Z & [v2,w2] in Z holds
          v1=v2 iff w1=w2
          proof
A15:        for v be object st v in V ex w be object st w in W & [v,w] in Z
            proof
              let v be object;
              assume v in V;
              then consider u1 be Element of U1 such that
A16:          ex u2 be Element of U2
              st v=[:u1,u2:] & u1 in U1\{{}} & u2 in U2\{{}};
              consider u2 be Element of U2 such that
A17:          v=[:u1,u2:] & u1 in U1\{{}} & u2 in U2\{{}} by A16;
              set w=[u1,u2];
              take w;
              thus thesis by A17,ZFMISC_1:def 2;
            end;
A18:        for w be object st w in W ex v be object st v in V & [v,w] in Z
            proof
              let w be object;
              assume w in W;
              then ex u1,u2 be object st u1 in U1\{{}} &
              u2 in U2\{{}} & w=[u1,u2] by ZFMISC_1:def 2;
              then consider u1,u2 be set such that
A19:          w=[u1,u2] & u1 in U1\{{}} & u2 in U2\{{}};
              set v=[:u1,u2:];
              take v;
              u1 is Element of U1 & u2 is Element of U2
              by A19,XBOOLE_1:36,TARSKI:def 3;
              hence thesis by A19;
            end;
            for v1,v2,w1,w2 be object st [v1,w1] in Z & [v2,w2] in Z holds
            v1=v2 iff w1=w2
            proof
              let v1,v2,w1,w2 be object;
              assume [v1,w1] in Z;
              then consider a1 be Element of U1, a2 be Element of U2 such that
A21:          [v1,w1]=[[:a1,a2:],[a1,a2]] &
              a1 in U1\{{}} & a2 in U2\{{}};
A22:          v1=[:a1,a2:] & w1=[a1,a2] by A21,XTUPLE_0:1;
              assume [v2,w2] in Z;
              then consider b1 be Element of U1, b2 be Element of U2 such that
A23:          [v2,w2]=[[:b1,b2:],[b1,b2]]&b1 in U1\{{}} & b2 in U2\{{}};
A24:          v2=[:b1,b2:] & w2=[b1,b2] by A23,XTUPLE_0:1;
              thus v1=v2 implies w1=w2
              proof
                assume
A25:            v1=v2;
                not a1 in {{}} & not a2 in {{}} by A21,XBOOLE_0:def 5;
                then a1 <> {} & a2 <>{} by TARSKI:def 1;
                then a1=b1 & a2=b2 by A22,A24,A25,ZFMISC_1:110;
                hence thesis by A21,A23,XTUPLE_0:1;
              end;
              assume
A26:          w1=w2;
              w1=[a1,a2] & w2=[b1,b2] by A21,A23,XTUPLE_0:1;
              then a1=b1 & a2=b2 by A26,XTUPLE_0:1;
              hence thesis by A21,A23,XTUPLE_0:1;
            end;
            hence thesis by A15,A18;
          end;
          ex Z be set st
          (for v be object st v in V ex w be object st w in W & [v,w] in Z)&
          (for w be object st w in W ex v be object st v in V & [v,w] in Z)&
          (for x,y,z,u be object st [x,y] in Z & [z,u] in Z holds
          x=z iff y=u)
          proof
            take Z;
            thus thesis by A14;
          end;
          hence thesis;
        end;
        hence thesis by A10,A13,YELLOW_8:4;
      end;
      union U=[:X1,X2:]
      proof
        set V2= {[:a,b:] where a is Element of U1\{{}},
        b is Element of U2\{{}} : a in U1\{{}} & b in U2\{{}}};
A26:    U=V2
        proof
          U1 is Subset-Family of X1 & U2 is Subset-Family of X2 by Lem9;
          hence thesis by A6,A8,A10,Lem8;
        end;
        union (U1\{{}})=union U1 & union(U2\{{}})=union U2 by PARTIT1:2;
        hence thesis by A3,A5,A7,A9,A26,LATTICE5:2;
      end;
      hence thesis by A12;
    end;
    hence thesis by Lem6a,SRINGS_1:def 4;
  end;
