reserve X for non empty TopSpace;
reserve Y for non empty TopStruct;

theorem Th8:
  for F being Subset-Family of Y st F is anti-discrete-set-family
  holds meet F <> {} implies union F is anti-discrete
proof
  let F be Subset-Family of Y;
  assume
A1: F is anti-discrete-set-family;
  assume
A2: meet F <> {};
  for G being Subset of Y st G is open holds (union F) misses G or union F c= G
  proof
    let G be Subset of Y;
    assume
A3: G is open;
    assume union F meets G;
    then consider A0 being set such that
A4: A0 in F and
A5: A0 meets G by ZFMISC_1:80;
    reconsider A0 as Subset of Y by A4;
    A0 is anti-discrete by A1,A4;
    then
A6: A0 c= G by A3,A5;
    meet F c= A0 by A4,SETFAM_1:3;
    then
A7: meet F c= G by A6;
    for B being set st B in F holds B c= G
    proof
      let B be set;
      assume
A8:   B in F;
      then reconsider B0 = B as Subset of Y;
      meet F c= B0 by A8,SETFAM_1:3;
      then B0 /\ G <> {} by A2,A7,XBOOLE_1:3,19;
      then
A9:   B0 meets G;
      B0 is anti-discrete by A1,A8;
      hence thesis by A3,A9;
    end;
    hence thesis by ZFMISC_1:76;
  end;
  hence thesis;
end;
