reserve a,b,c for set;

theorem Th8:
  for T1,T2 being TopSpace st the carrier of T1 = the carrier of T2
& for A1 being Subset of T1, A2 being Subset of T2 st A1 = A2 holds Cl A1 = Cl
  A2 holds the topology of T1 = the topology of T2
proof
  let T1,T2 be TopSpace such that
A1: the carrier of T1 = the carrier of T2 and
A2: for A1 being Subset of T1, A2 being Subset of T2 st A1 = A2 holds Cl
  A1 = Cl A2;
  now
    let A be set;
    thus A is closed Subset of T1 implies A is closed Subset of T2
    proof
      assume A is closed Subset of T1;
      then reconsider A1 = A as closed Subset of T1;
      reconsider A2 = A1 as Subset of T2 by A1;
      Cl A1 = A1 by PRE_TOPC:22;
      then Cl A2 = A2 by A2;
      hence thesis;
    end;
    assume A is closed Subset of T2;
    then reconsider A2 = A as closed Subset of T2;
    reconsider A1 = A2 as Subset of T1 by A1;
    Cl A2 = A2 by PRE_TOPC:22;
    then Cl A1 = A1 by A2;
    hence A is closed Subset of T1;
  end;
  then the TopStruct of T1 = the TopStruct of T2 by Th6;
  hence thesis;
end;
