reserve A,B for Ordinal,
        o for object,
        x,y,z for Surreal,
        n for Nat,
        r,r1,r2 for Real;

theorem Th90:
  for r be non-zero Sequence of REAL,
    y be Sequence, s be Surreal-Sequence
  for A,B be Ordinal st B in A c= dom r/\dom y & A c= dom s
    for yb be Surreal st yb = y.B &
      x in_meets_terms s,y,r,A & z in_meets_terms s,y,r,A
  holds |.x - z.| infinitely< No_omega^ yb
proof
  let r be non-zero Sequence of REAL, y be Sequence,
      s be Surreal-Sequence;
  let A,B be Ordinal such that
A1: B in A c= dom r/\dom y & A c= dom s;
  let yb be Surreal such that
A2: yb = y.B and
A3: x in_meets_terms s,y,r,A & z in_meets_terms s,y,r,A;
  s.B in rng s by A1,FUNCT_1:def 3;
  then reconsider sB=s.B as Surreal by SURREAL0:def 16;
  set S = sB + uReal.(r.B)* No_omega^ yb;
  x is (sB,yb,r.B)_term & z is (sB,yb,r.B)_term by A1,A2,A3;
  then |. x - S.| infinitely< No_omega^yb &
  |. z - S.| infinitely< No_omega^yb by Th73;
  then
A4: |. x - S -(z - S) .| infinitely< No_omega^yb by Th43;
A5: (-S) -(-S) ==0_No by SURREALR:39;
  x +- S + -(z +- S) = x +- S + (- -S +- z) by SURREALR:40
  .= x +- S + - -S +- z by SURREALR:37
  .= x + (- S + - -S) +- z by SURREALR:37
  .= (- S + - -S) +(- z +x) by SURREALR:37;
  then x - S -(z - S) == (x- z)+0_No = x-z by A5,SURREALR:43;
  then |. x - S + -(z - S) .| == |. x-z .| by Th48;
  hence thesis by Th11,A4;
end;
