reserve
  S for (4,1) integer bool-correct non empty non void BoolSignature,
  X for non-empty ManySortedSet of the carrier of S,
  T for vf-free integer all_vars_including inheriting_operations free_in_itself
  (X,S)-terms VarMSAlgebra over S,
  C for (4,1) integer bool-correct non-empty image of T,
  G for basic GeneratorSystem over S,X,T,
  A for IfWhileAlgebra of the generators of G,
  I for integer SortSymbol of S,
  x,y,z,m for pure (Element of (the generators of G).I),
  b for pure (Element of (the generators of G).the bool-sort of S),
  t,t1,t2 for Element of T,I,
  P for Algorithm of A,
  s,s1,s2 for Element of C-States(the generators of G);
reserve
  f for ExecutionFunction of A, C-States(the generators of G),
  (\falseC)-States(the generators of G, b);
reserve u for ManySortedFunction of FreeGen T, the Sorts of C;
reserve
  S for 1-1-connectives (4,1) integer (11,1,1)-array 11 array-correct
  bool-correct non empty non void BoolSignature,
  X for non-empty ManySortedSet of the carrier of S,
  T for vf-free all_vars_including inheriting_operations free_in_itself
  (X,S)-terms integer-array non-empty VarMSAlgebra over S,
  C for (11,1,1)-array (4,1) integer bool-correct non-empty image of T,
  G for basic GeneratorSystem over S,X,T,
  A for IfWhileAlgebra of the generators of G,
  I for integer SortSymbol of S,
  x,y,m,i for pure (Element of (the generators of G).I),
  M,N for pure (Element of (the generators of G).the_array_sort_of S),
  b for pure (Element of (the generators of G).the bool-sort of S),
  s,s1 for (Element of C-States(the generators of G));
reserve u for ManySortedFunction of FreeGen T, the Sorts of C;

theorem
  for j being Integer st j in dom (s.(the_array_sort_of S).M) &
  M.(j,I) in (the generators of G).I
  holds s.(the_array_sort_of S).M.j = s.I.(M.(j,I))
  proof
    let j be Integer;
    assume
A1: j in dom (s.(the_array_sort_of S).M);
    assume
A2: M.(j,I) in (the generators of G).I;
    reconsider s1 = s as ManySortedFunction of the generators of G,
    the Sorts of C by AOFA_A00:48;
    consider h being ManySortedFunction of T,C such that
A3: h is_homomorphism T,C & s1 = h||the generators of G by AOFA_A00:def 19;
A4: ^(j,T,I) value_at(C,s) = j & @M value_at(C,s) = s.(the_array_sort_of S).M
    by Th61,Th90;
    s.I.(M.(j,I)) = (h.I)|((the generators of G).I).(M.(j,I))
    by A3,MSAFREE:def 1
    .= h.I.(@M.(^(j,T,I))) by A2,FUNCT_1:49
    .= @M.(^(j,T,I)) value_at(C,s) by A3,Th29
    .= (@M value_at(C,s)).(^(j,T,I) value_at(C,s)) by Th79
    .= (s1.(the_array_sort_of S).M).j by A1,A4,Th74;
    hence s.(the_array_sort_of S).M.j = s.I.(M.(j,I));
  end;
