reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th91:
  for H,K,H9,K9 being strict StableSubgroup of G, JH being normal
StableSubgroup of H9"\/"(H/\K), HK being normal StableSubgroup of H/\K st H9 is
normal StableSubgroup of H & K9 is normal StableSubgroup of K & JH = H9"\/"(H/\
  K9) & HK=(H9/\K)"\/"(K9/\H) holds (H9"\/"(H/\K))./.JH, (H/\K)./.HK
  are_isomorphic
proof
  let H,K,H9,K9 be strict StableSubgroup of G;
  reconsider GG = H as GroupWithOperators of O;
  set G9=H/\K;
  set L=H/\K9;
  reconsider G9 as strict StableSubgroup of GG by Lm33;
  let JH be normal StableSubgroup of H9"\/"(H/\K);
  let HK be normal StableSubgroup of H/\K;
  assume that
A1: H9 is normal StableSubgroup of H and
A2: K9 is normal StableSubgroup of K;
A3: L is normal StableSubgroup of G9 by A2,Th60;
  reconsider N9 = H9 as normal StableSubgroup of GG by A1;
  assume that
A4: JH = H9"\/"(H/\K9) and
A5: HK=(H9/\K)"\/"(K9/\H);
  reconsider N = N9 as StableSubgroup of GG;
  set N1=G9/\N;
A6: G9"\/"N = (H/\K) "\/" H9 by Th86
    .= H9"\/"(H/\K);
  reconsider L as StableSubgroup of GG by A3,Th11;
  N1=(H/\K)/\H9 by Th39;
  then
A7: L"\/"N1 = (H/\K9)"\/"((H/\K)/\H9) by Th86
    .= ((H9/\H)/\K)"\/"(K9/\H) by Th20
    .= HK by A1,A5,Lm21;
  reconsider HH = GG./.N9 as GroupWithOperators of O;
  reconsider f = nat_hom N9 as Homomorphism of GG,HH;
A8: N = Ker f by Th48;
  L"\/"N = (H/\K9)"\/"H9 by Th86
    .=JH by A4;
  hence thesis by A3,A7,A8,A6,Th90;
end;
