reserve x,x0, r, s, h for Real,

  n for Element of NAT,
  rr, y for set,
  Z for open Subset of REAL,

  f, f1, f2 for PartFunc of REAL,REAL;

theorem Th91:
  Z c= dom (( #Z n)*(arctan)) & Z c=].-1,1.[ implies ( #Z n)*(
arctan) is_differentiable_on Z & for x st x in Z holds ((( #Z n)*arctan)`|Z).x
  = n*(arctan.x) #Z (n-1) / (1+x^2)
proof
  assume that
A1: Z c= dom (( #Z n)*arctan) and
A2: Z c= ].-1,1.[;
A3: for x st x in Z holds ( #Z n)*arctan is_differentiable_in x
  proof
    let x;
    assume
A4: x in Z;
    arctan is_differentiable_on Z by A2,Th81;
    then arctan is_differentiable_in x by A4,FDIFF_1:9;
    hence thesis by TAYLOR_1:3;
  end;
  then
A5: ( #Z n)*(arctan) is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((( #Z n)*(arctan))`|Z).x = n*(arctan.x) #Z (n-1)
  / (1+x^2)
  proof
    let x;
    assume
A6: x in Z;
    then
A7: -1 < x by A2,XXREAL_1:4;
    arctan is_differentiable_on Z by A2,Th81;
    then
A8: arctan is_differentiable_in x by A6,FDIFF_1:9;
A9: x < 1 by A2,A6,XXREAL_1:4;
    ((( #Z n)*arctan)`|Z).x = diff(( #Z n)*arctan,x) by A5,A6,FDIFF_1:def 7
      .= (n*((arctan.x) #Z (n-1))) * diff(arctan,x) by A8,TAYLOR_1:3
      .= (n*((arctan.x) #Z (n-1))) *(1/(1+x^2)) by A7,A9,Th75
      .= n*(arctan.x) #Z (n-1) / (1+x^2);
    hence thesis;
  end;
  hence thesis by A1,A3,FDIFF_1:9;
end;
