reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem
  for M being non empty MetrSpace, A being Subset of TopSpaceMetr M, p
  being Point of M holds p in Cl A iff for r being Real st r > 0 holds
  Ball (p, r) meets A
proof
  let M be non empty MetrSpace, A be Subset of TopSpaceMetr M, p be Point of M;
  reconsider p9 = p as Point of TopSpaceMetr M by TOPMETR:12;
  hereby
    assume
A1: p in Cl A;
    let r be Real;
    reconsider B = Ball (p, r) as Subset of TopSpaceMetr M by TOPMETR:12;
    assume r > 0;
    then B is a_neighborhood of p9 by Th91;
    hence Ball (p, r) meets A by A1,CONNSP_2:27;
  end;
  assume
A2: for r being Real st r > 0 holds Ball (p, r) meets A;
  for G being a_neighborhood of p9 holds G meets A
  proof
    let G be a_neighborhood of p9;
    p in Int G by CONNSP_2:def 1;
    then ex r being Real st r > 0 & Ball (p, r) c= G by Th4;
    hence thesis by A2,XBOOLE_1:63;
  end;
  hence thesis by CONNSP_2:27;
end;
