reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th92:
  for H,K,H9,K9 being strict StableSubgroup of G st H9 is normal
  StableSubgroup of H & K9 is normal StableSubgroup of K holds H9"\/"(H/\K9) is
  normal StableSubgroup of H9"\/"(H/\K)
proof
  let H,K,H9,K9 be strict StableSubgroup of G;
  reconsider GG=H as GroupWithOperators of O;
  reconsider G9=H/\K as strict StableSubgroup of GG by Lm33;
  assume that
A1: H9 is normal StableSubgroup of H and
A2: K9 is normal StableSubgroup of K;
  reconsider N9=H9 as normal StableSubgroup of GG by A1;
  reconsider N=N9 as StableSubgroup of GG;
  reconsider HH=GG./.N9 as GroupWithOperators of O;
  reconsider f=nat_hom N9 as Homomorphism of GG,HH;
  set L=H/\K9;
A3: L is strict normal StableSubgroup of G9 by A2,Th60;
  then reconsider L as strict StableSubgroup of GG by Th11;
A4: N = Ker f by Th48;
A5: G9"\/"N = (H/\K)"\/"H9 by Th86
    .= H9"\/"(H/\K);
  L"\/"N = (H/\K9)"\/"H9 by Th86
    .= H9"\/"(H/\K9);
  hence thesis by A3,A4,A5,Th90;
end;
