
theorem Th91:
for X1,X2 be non empty set, S1 be SigmaField of X1, S2 be SigmaField of X2,
  M1 be sigma_Measure of S1, E be Element of sigma measurable_rectangles(S1,S2)
st M1 is sigma_finite
holds
  (ex F be Function of X2,ExtREAL st
    (for y be Element of X2 holds
         F.y = M1.(Measurable-Y-section(E,y)))
  & (for V be Element of S2 holds F is V-measurable))
proof
   let X1,X2 be non empty set, S1 be SigmaField of X1, S2 be SigmaField of X2,
   M1 be sigma_Measure of S1,
   E be Element of sigma measurable_rectangles(S1,S2);
   assume M1 is sigma_finite; then
   consider B be Set_Sequence of S1 such that
A1: B is non-descending & (for n be Nat holds M1.(B.n) < +infty)
  & lim B = X1 by LM0902a;

   defpred P[Nat,object] means
    ex f1 be Function of X2,ExtREAL st
     $2 = f1
   & (for y be Element of X2 holds
        f1.y = M1.(Measurable-Y-section(E,y) /\ B.$1)
   & (for V be Element of S2 holds f1 is V-measurable));

A2:for n be Element of NAT ex f be Element of PFuncs(X2,ExtREAL) st P[n,f]
   proof
    let n be Element of NAT;

    reconsider Bn = B.n as Element of S1 by MEASURE8:def 2;
    M1.Bn < +infty by A1; then
    sigma measurable_rectangles(S1,S2)
     c= {E where E is Element of sigma measurable_rectangles(S1,S2) :
       (ex F be Function of X2,ExtREAL st
            (for y be Element of X2 holds
               F.y = M1.(Measurable-Y-section(E,y) /\ Bn))
          & (for V be Element of S2 holds F is V-measurable))}
        by Th89; then
    E in {E where E is Element of sigma measurable_rectangles(S1,S2) :
      (ex F be Function of X2,ExtREAL st
           (for y be Element of X2 holds
               F.y = M1.(Measurable-Y-section(E,y) /\ Bn))
         & (for V be Element of S2 holds F is V-measurable))}; then
    ex E1 be Element of sigma measurable_rectangles(S1,S2) st
     E = E1
   & (ex F be Function of X2,ExtREAL st
         (for y be Element of X2 holds
             F.y = M1.(Measurable-Y-section(E1,y) /\ Bn))
       & (for V be Element of S2 holds F is V-measurable)); then
    consider f1 be Function of X2,ExtREAL such that
A3:   (for y be Element of X2 holds
         f1.y = M1.(Measurable-Y-section(E,y) /\ Bn))
    & (for V be Element of S2 holds f1 is V-measurable);

    reconsider f = f1 as Element of PFuncs(X2,ExtREAL) by PARTFUN1:45;
    take f;
    f1 is Function of X2,ExtREAL & f = f1
  & (for y be Element of X2 holds
        f1.y = M1.(Measurable-Y-section(E,y) /\ B.n))
  & (for V be Element of S2 holds f1 is V-measurable) by A3;
    hence thesis;
   end;

   consider f be Function of NAT,PFuncs(X2,ExtREAL) such that
A4: for n be Element of NAT holds P[n,f.n] from FUNCT_2:sch 3(A2);

A5:for n be Nat holds
    f.n is Function of X2,ExtREAL
  & (for y be Element of X2 holds
        (f.n).y = M1.(Measurable-Y-section(E,y) /\ B.n)
  & (for V be Element of S2 holds f.n is V-measurable))
   proof
    let n be Nat;
    n is Element of NAT by ORDINAL1:def 12; then
    ex f1 be Function of X2,ExtREAL st
     f.n = f1
   & (for y be Element of X2 holds
        f1.y = M1.(Measurable-Y-section(E,y) /\ B.n)
   & (for V be Element of S2 holds f1 is V-measurable)) by A4;
    hence thesis;
   end;
   for n,m be Nat holds dom(f.n) = dom(f.m)
   proof
    let n,m be Nat;
    f.n is Function of X2,ExtREAL & f.m is Function of X2,ExtREAL by A5; then
    dom(f.n) = X2 & dom(f.m) = X2 by FUNCT_2:def 1;
    hence thesis;
   end; then
   reconsider f as with_the_same_dom Functional_Sequence of X2,ExtREAL
     by MESFUNC8:def 2;
   reconsider XX2 = X2 as Element of S2 by MEASURE1:11;
   f.0 is Function of X2,ExtREAL by A5; then
A6:dom(f.0) = XX2 by FUNCT_2:def 1;
A7:for n be Nat holds f.n is XX2-measurable by A5;
A11:for y be Element of X2 st y in X2 holds f#y is convergent
   proof
    let y be Element of X2;
    assume y in X2;
    for n,m be Nat st m <= n holds (f#y).m <= (f#y).n
    proof
     let n,m be Nat;
     assume A8: m <= n;
     (f#y).m = (f.m).y & (f#y).n = (f.n).y by MESFUNC5:def 13; then
A9:  (f#y).m = M1.(Measurable-Y-section(E,y) /\ B.m)
   & (f#y).n = M1.(Measurable-Y-section(E,y) /\ B.n) by A5;
A10: Measurable-Y-section(E,y) /\ B.m c= Measurable-Y-section(E,y) /\ B.n
       by A1,A8,PROB_1:def 5,XBOOLE_1:26;
     B.m in S1 & B.n in S1 by MEASURE8:def 2; then
     Measurable-Y-section(E,y) /\ B.m in S1 &
     Measurable-Y-section(E,y) /\ B.n in S1 by MEASURE1:11;
     hence (f#y).m <= (f#y).n by A9,A10,MEASURE1:31;
    end; then
    f#y is non-decreasing by RINFSUP2:7;
    hence f#y is convergent by RINFSUP2:37;
   end;
A12:dom (lim f) = X2 by A6,MESFUNC8:def 9; then
   reconsider F = lim f as Function of X2,ExtREAL by FUNCT_2:def 1;
   take F;
   thus for y be Element of X2 holds F.y = M1.(Measurable-Y-section(E,y))
   proof
    let y be Element of X2;
    deffunc F(Nat) = Measurable-Y-section(E,y) /\ B.$1;
    set K1 = Measurable-Y-section(E,y) (/\) B;
    B is convergent by A1,SETLIM_1:80; then
    lim K1 = Measurable-Y-section(E,y) /\ X1 by A1,SETLIM_2:92; then
A13:lim K1 = Measurable-Y-section(E,y) by XBOOLE_1:28;
A14:dom K1 = NAT by FUNCT_2:def 1;
    for n be object st n in NAT holds K1.n in S1
    proof
     let n be object;
     assume n in NAT; then
     reconsider n1=n as Element of NAT;
A15: K1.n1 = Y-section(E,y) /\ B.n1 by SETLIM_2:def 5;
     reconsider Bn = B.n1 as Element of S1 by MEASURE8:def 2;
     for y be Element of X2 holds Y-section(E,y) /\ Bn in S1
     proof
      let y be Element of X2;
      Y-section(E,y) in S1 by Th44;
      hence Y-section(E,y) /\ Bn in S1 by MEASURE1:11;
     end;
     hence K1.n in S1 by A15;
    end; then
    reconsider K1 as SetSequence of S1 by A14,FUNCT_2:3;
    K1 is non-descending by A1,SETLIM_2:22; then
A16:lim(M1*K1) = M1.(Measurable-Y-section(E,y)) by A13,MEASURE8:26;
    for n be Element of NAT holds (f#y).n = (M1*K1).n
    proof
     let n be Element of NAT;
     (f#y).n = (f.n).y by MESFUNC5:def 13; then
A17: (f#y).n = M1.(Measurable-Y-section(E,y) /\ B.n) by A5;
     K1.n = Measurable-Y-section(E,y) /\ B.n by SETLIM_2:def 5;
     hence (f#y).n = (M1*K1).n by A14,A17,FUNCT_1:13;
    end; then
    lim(f#y) = M1.(Measurable-Y-section(E,y)) by A16,FUNCT_2:63;
    hence F.y = M1.(Measurable-Y-section(E,y)) by A12,MESFUNC8:def 9;
   end;
   thus for V be Element of S2 holds F is V-measurable by A11,MESFUNC1:30,
   A6,A7,MESFUNC8:25;
end;
