reserve J,J1,K for Element of Segm 13,
  b,b1,b2,c,c1,c2 for Element of SCM+FSA-Data-Loc,
  f,f1,f2 for Element of SCM+FSA-Data*-Loc;
reserve k for Nat,
  J,K,L for Element of Segm 13,
  O,P,R for Element of Segm 9;
reserve da for Int-Location,
  fa for FinSeq-Location,
  x,y for set;
reserve la,lb for Nat,
  La for Nat,
  i for Instruction of SCM+FSA,
  I for Instruction of SCM,
  l for Nat,
  LA,LB for Nat,
  dA,dB,dC,dD for Element of SCM+FSA-Data-Loc,
  DA,DB,DC for Element of SCM-Data-Loc,
  fA,fB,fC for Element of SCM+FSA-Data*-Loc,
  f,g for FinSeq-Location,
  A,B for Data-Location,
  a,b,c,db for Int-Location;
reserve S for State of SCM,
  s,s1 for State of SCM+FSA;

theorem Th85:
  for I be Instruction of SCM+FSA st InsCode I = 0 holds I = [0,{},{}]
proof
  let I be Instruction of SCM+FSA such that
A1: InsCode I = 0;
A2: now
    assume I in { [R,{},<*DA,DC*>] : R in { 1,2,3,4,5} };
    then ex R,DA,DC st I = [R,{},<*DA,DC*>] & R in { 1,2,3,4,5};
    hence contradiction by A1;
  end;
A3: now
    assume I in { [O,<*LA*>,{}] : O = 6 };
    then ex O,LA st I = [O,<*LA*>,{}] & O = 6;
    hence contradiction by A1;
  end;
A4: now
    assume I in { [P,<*LB*>,<*DB*>] : P in { 7,8 } };
    then ex P,LB,DB st I = [P,<*LB*>,<*DB*>] & P in { 7,8 };
    hence contradiction by A1;
  end;
A5:  now
    assume I in { [K,{},<*dC,fB*>] : K in {11,12} };
    then ex K,dC,fB st I = [K,{},<*dC,fB*>] & K in {11,12};
    hence contradiction by A1;
  end;
A6: I in SCM-Instr \/ { [L,{},<*dB,fA,dA*>] where L is Element of Segm 13,
    dA,dB is Element of SCM+FSA-Data-Loc,fA is Element of SCM+FSA-Data*-Loc:
    L in {9,10} }
        by A5,XBOOLE_0:def 3;
  now
    assume I in { [L,{},<*dB,fA,dA*>] where L is Element of Segm 13,
    dA,dB is Element of SCM+FSA-Data-Loc,fA is Element of SCM+FSA-Data*-Loc
    : L in {9,10} };
    then ex L be Element of Segm 13,
    dA,dB be Element of SCM+FSA-Data-Loc,fA be Element of SCM+FSA-Data*-Loc
    st I = [L,{},<*dB,fA,dA*>] & L in {9,10};
    hence contradiction by A1;
  end;
  then I in SCM-Instr by A6,XBOOLE_0:def 3;
  then
  I in { [SCM-Halt,{},{}] } \/ { [O,<*LA*>,{}] : O = 6 }
   \/ { [P,<*LB*>,<*DB*>] : P in { 7,8 } } by A2,XBOOLE_0:def 3;
  then I in { [SCM-Halt,{},{}] } \/ { [O,<*LA*>,{}] : O = 6 }
   by A4,XBOOLE_0:def 3;
  then I in { [SCM-Halt,{},{}] } by A3,XBOOLE_0:def 3;
  hence thesis by TARSKI:def 1;
end;
