reserve x,x0, r, s, h for Real,

  n for Element of NAT,
  rr, y for set,
  Z for open Subset of REAL,

  f, f1, f2 for PartFunc of REAL,REAL;

theorem Th92:
  Z c= dom (( #Z n)*(arccot)) & Z c=].-1,1.[ implies ( #Z n)*(
arccot) is_differentiable_on Z & for x st x in Z holds ((( #Z n)*arccot)`|Z).x
  = -n*(arccot.x) #Z (n-1) / (1+x^2)
proof
  assume that
A1: Z c= dom (( #Z n)*arccot) and
A2: Z c= ].-1,1.[;
A3: for x st x in Z holds ( #Z n)*arccot is_differentiable_in x
  proof
    let x;
    assume
A4: x in Z;
    arccot is_differentiable_on Z by A2,Th82;
    then arccot is_differentiable_in x by A4,FDIFF_1:9;
    hence thesis by TAYLOR_1:3;
  end;
  then
A5: ( #Z n)*(arccot) is_differentiable_on Z by A1,FDIFF_1:9;
  for x st x in Z holds ((( #Z n)*(arccot))`|Z).x = -n*(arccot.x) #Z (n-1)
  / (1+x^2)
  proof
    let x;
    assume
A6: x in Z;
    then
A7: -1 < x by A2,XXREAL_1:4;
    arccot is_differentiable_on Z by A2,Th82;
    then
A8: arccot is_differentiable_in x by A6,FDIFF_1:9;
A9: x < 1 by A2,A6,XXREAL_1:4;
    ((( #Z n)*arccot)`|Z).x = diff(( #Z n)*arccot,x) by A5,A6,FDIFF_1:def 7
      .= (n*((arccot.x) #Z (n-1))) * diff(arccot,x) by A8,TAYLOR_1:3
      .= (n*((arccot.x) #Z (n-1))) * (-1/(1+x^2)) by A7,A9,Th76
      .= -n*(arccot.x) #Z (n-1) / (1+x^2);
    hence thesis;
  end;
  hence thesis by A1,A3,FDIFF_1:9;
end;
