reserve A,B for Ordinal,
        o for object,
        x,y,z for Surreal,
        n for Nat,
        r,r1,r2 for Real;

theorem Th92:
  for r be non-zero Sequence of REAL,
       y be strictly_decreasing Surreal-Sequence st
       z in_meets_terms Partial_Sums(r,y),y,r,dom r/\dom y &
  not z == Sum(r,y)
     for A be Ordinal,yA be Surreal st A in dom r/\dom y & yA = y.A holds
         omega-y ( Sum(r,y) - z) < yA
proof
  let r be non-zero Sequence of REAL;
  let y be strictly_decreasing Surreal-Sequence;
  set s = Partial_Sums(r,y),D=dom r/\dom y;
  assume that
A1: z in_meets_terms s,y,r,D and
A2: not z == Sum(r,y);
  let A be Ordinal,yA be Surreal;
  assume
A3: A in D & yA=y.A;
A4: not Sum(r,y) - z == 0_No by SURREALR:47,A2;
A5: Sum(r,y) in_meets_terms s,y,r,D by Th89;
  dom Partial_Sums(r,y) =succ D by Def17;
  then
A6: |.Sum(r,y) -z.| infinitely< No_omega^ yA
  by XBOOLE_1:7,A5,A3,A1,Th90;
  |.Sum(r,y) +-z.|, No_omega^ omega-y (Sum(r,y) +-z) are_commensurate
  by A4,Def7;
  then No_omega^ omega-y (Sum(r,y) +-z) < No_omega^ yA by Th9,A6,Th15;
  hence thesis by Lm5;
end;
