
theorem
  for G being _Graph, P being Path of G st P is open & P is chordless
  for m,n being odd Nat st m < n & n <= len P holds P.cut(m,n) is
  chordless & P.cut(m,n) is open
proof
  let G be _Graph, P be Path of G such that
A1: P is open and
A2: P is chordless;
  let m,n be odd Nat such that
A3: m < n and
A4: n <= len P;
  set Q = P.cut(m,n);
A5: n in NAT by ORDINAL1:def 12;
A6: m in NAT by ORDINAL1:def 12;
  now
    assume Q is chordal;
    then consider i,j being odd Nat such that
A7: i+2 < j and
A8: j <= len Q and
    Q.i <> Q.j and
A9: ex e being object st e Joins Q.i,Q.j,G and
    for f being object st f in Q.edges() holds not f Joins Q.i,Q.j,G;
    consider e being object such that
A10: e Joins Q.i,Q.j,G by A9;
    set mi = m+i-1;
    set mj = m+j-1;
    1 <= j by Th2;
    then
A11: j in dom Q by A8,FINSEQ_3:25;
    then
A12: Q.j = P.mj by A3,A4,A6,A5,GLIB_001:47;
A13: mj in dom P by A3,A4,A6,A5,A11,GLIB_001:47;
    i+0<i+2 by XREAL_1:8;
    then i<j by A7,XXREAL_0:2;
    then
A14: i < len Q by A8,XXREAL_0:2;
    1 <= i by Th2;
    then
A15: i in dom Q by A14,FINSEQ_3:25;
    then
A16: mi in dom P by A3,A4,A6,A5,GLIB_001:47;
    reconsider mj as odd Element of NAT by A13;
    reconsider mj as odd Nat;
A17: mj <= len P by A13,FINSEQ_3:25;
    reconsider mi as odd Element of NAT by A16;
    reconsider mi as odd Nat;
    i+2+m < j+m by A7,XREAL_1:8;
    then
A18: m+i+2-1 < m+j-1 by XREAL_1:9;
    then
A19: mi+2 < mj;
    mi+0 < mi+2 by XREAL_1:8;
    then
A20: mi < mj by A18,XXREAL_0:2;
    e Joins P.mi,P.mj,G by A3,A4,A6,A5,A10,A15,A12,GLIB_001:47;
    hence contradiction by A1,A2,A19,A20,A17,Th91;
  end;
  hence Q is chordless;
  now
    assume Q is closed;
    then
A21: Q.first() = Q.last();
A22: P.n = Q.last() by A3,A4,A6,A5,GLIB_001:37;
    P.m = Q.first() by A3,A4,A6,A5,GLIB_001:37;
    hence contradiction by A1,A3,A4,A6,A5,A21,A22,GLIB_001:147;
  end;
  hence thesis;
end;
