
theorem Th93:
  for f be Function of [:NAT,NAT:],ExtREAL st
   f is P-convergent_to_+infty holds
    not f is P-convergent_to_-infty &
    not f is P-convergent_to_finite_number
proof
   let f be Function of [:NAT,NAT:],ExtREAL;
   assume A1: f is P-convergent_to_+infty;
   hereby assume f is P-convergent_to_-infty; then
    consider N1 be Nat such that
A3:  for n,m be Nat st n>=N1 & m>=N1 holds f.(n,m) <= -1;
    consider N2 be Nat such that
A4:  for n,m be Nat st n>=N2 & m>=N2 holds 1 <= f.(n,m) by A1;
    reconsider N1,N2 as Element of NAT by ORDINAL1:def 12;
    set N = max(N1,N2);
A5: N>=N1 & N>=N2 by XXREAL_0:25; then
    f.(N,N) <= -1 by A3;
    hence contradiction by A4,A5;
   end;
   assume f is P-convergent_to_finite_number; then
   consider p be Real such that
A6: for e be Real st 0<e
     ex N be Nat st
      for n,m be Nat st n>=N & m>=N holds
       |. f.(n,m) - p qua ExtReal .| < e;
   reconsider p1=p as ExtReal;
   per cases;
   suppose A9: p > 0;
    then consider N1 be Nat such that
A7: for n,m be Nat st n>=N1 & m>=N1 holds |.f.(n,m)- p1.| < p by A6;
A8: now
     let n,m be Nat;
     assume n>=N1 & m>=N1;
     then |.f.(n,m)- p qua ExtReal.| <  p by A7;
     then f.(n,m) -  p1 <  p by EXTREAL1:21;
     then f.(n,m) < (p1+p1) by XXREAL_3:54;
     then f.(n,m) < 2*p1 by XXREAL_3:94;
     hence f.(n,m) < (2*p) by XXREAL_3:def 5;
    end;
    consider N2 be Nat such that
A10: for n,m be Nat st n>=N2 & m>=N2 holds (2*p) <= f.(n,m) by A1,A9;
    reconsider N1,N2 as Element of NAT by ORDINAL1:def 12;
    set N = max(N1,N2);
A11:N>=N1 & N>=N2 by XXREAL_0:25; then
    f.(N,N) < (2*p) by A8;
    hence contradiction by A11,A10;
   end;
   suppose A12: p = 0;
    consider N1 be Nat such that
A13: for n,m be Nat st n>=N1 & m>=N1 holds |. f.(n,m)- p .| <  1 by A6;
    consider N2 be Nat such that
A14: for n,m be Nat st n>=N2 & m>=N2 holds 1 <= f.(n,m) by A1;
    reconsider N1,N2 as Element of NAT by ORDINAL1:def 12;
    reconsider jj =1 as ExtReal;
    set N = max(N1,N2);
A15:N>=N1 & N>=N2 by XXREAL_0:25; then
    |. f.(N,N)- p1 .| <  jj by A13;
    then f.(N,N) -  p1 <  jj by EXTREAL1:21;
    then f.(N,N) <  jj + p1 by XXREAL_3:54;
    then f.(N,N) <  1 + 0 by  A12,XXREAL_3:def 2;
    hence contradiction by A14,A15;
   end;
   suppose p < 0; then
    consider N1 be Nat such that
A17: for n,m be Nat st n>=N1 & m>=N1 holds |.f.(n,m) - p .| < -p by A6;
A18:now let n,m be Nat;
     assume n>=N1 & m>=N1; then
     |.f.(n,m) -p.| < -p by A17; then
     f.(n,m) - p1 < -p by EXTREAL1:21; then
     f.(n,m) < p1+(-p) by XXREAL_3:54; then
     f.(n,m) < p+(-p) by XXREAL_3:def 2;
     hence f.(n,m) < 0;
    end;
    consider N2 be Nat such that
A19: for n,m be Nat st n>=N2 & m>=N2 holds 1 <= f.(n,m) by A1;
    reconsider N1,N2 as Element of NAT by ORDINAL1:def 12;
    set N = max(N1,N2);
A20:N>=N1 & N>=N2 by XXREAL_0:25; then
    f.(N,N) < 0 by A18;
    hence contradiction by A19,A20;
   end;
end;
