reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem
  for A be Subset of TOP-REAL n for p be Point of TOP-REAL n for p9 be
  Point of Euclid n st p = p9 for s be Real st s > 0 holds p in Cl A iff
  for r be Real st 0 < r & r < s holds Ball (p9,r) meets A
proof
  let A be Subset of TOP-REAL n;
  let p be Point of TOP-REAL n;
  let p9 be Point of Euclid n;
  assume
A1: p = p9;
  let s be Real;
  assume
A2: s > 0;
  hereby
    assume
A3: p in Cl A;
    let r be Real;
    assume that
A4: 0 < r and
    r < s;
    reconsider B = Ball (p9,r) as Subset of TOP-REAL n by TOPREAL3:8;
    B is a_neighborhood of p by A1,A4,Th2;
    hence Ball (p9, r) meets A by A3,CONNSP_2:27;
  end;
  assume
A5: for r be Real st 0 < r & r < s holds Ball (p9,r) meets A;
  for G be a_neighborhood of p holds G meets A
  proof
    let G be a_neighborhood of p;
    p in Int G by CONNSP_2:def 1;
    then consider r9 be Real such that
A6: r9 > 0 and
A7: Ball (p9,r9) c= G by A1,Th5;
    set r = min(r9,s/2);
    Ball (p9,r) c= Ball (p9,r9) by PCOMPS_1:1,XXREAL_0:17;
    then
A8: Ball (p9,r) c= G by A7;
    s/2 < s & r <= s/2 by A2,XREAL_1:216,XXREAL_0:17;
    then
A9: r < s by XXREAL_0:2;
    s/2 > 0 by A2,XREAL_1:215;
    then r > 0 by A6,XXREAL_0:15;
    hence thesis by A5,A8,A9,XBOOLE_1:63;
  end;
  hence thesis by CONNSP_2:27;
end;
