reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th93:
  for H,K,H9,K9 being strict StableSubgroup of G, JH being normal
StableSubgroup of H9"\/"(H/\K), JK being normal StableSubgroup of K9"\/"(K/\H)
st JH = H9"\/"(H/\K9) & JK= K9"\/"(K/\H9) & H9 is normal StableSubgroup of H &
K9 is normal StableSubgroup of K holds (H9"\/"(H/\K))./.JH, (K9"\/"(K/\H))./.JK
  are_isomorphic
proof
  let H,K,H9,K9 be strict StableSubgroup of G;
  let JH be normal StableSubgroup of H9"\/"(H/\K);
  let JK be normal StableSubgroup of K9"\/"(K/\H);
  assume that
A1: JH = H9"\/"(H/\K9) and
A2: JK= K9"\/"(K/\H9);
  set HK=(H9/\K)"\/"(K9/\H);
  assume
A3: H9 is normal StableSubgroup of H;
  then
A4: H9/\K is normal StableSubgroup of H/\K by Th60;
  assume
A5: K9 is normal StableSubgroup of K;
  then K9/\H is normal StableSubgroup of H/\K by Th60;
  then reconsider HK as normal StableSubgroup of H/\K by A4,Th87;
  HK=(K9/\H)"\/"(H9/\K);
  then
A6: (K9"\/"(K/\H))./.JK, (H/\K)./.HK are_isomorphic by A2,A3,A5,Th91;
  (H9"\/"(H/\K))./.JH, (H/\K)./.HK are_isomorphic by A1,A3,A5,Th91;
  hence thesis by A6,Th55;
end;
