reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;
reserve D for non vertical non horizontal non empty compact Subset of TOP-REAL
  2;

theorem Th77:
  for B being Subset of TOP-REAL 2 st B is_a_component_of (L~
  SpStSeq D)` & not B is bounded holds B=LeftComp SpStSeq D
proof
  let B be Subset of TOP-REAL 2;
  set f = SpStSeq D;
  assume that
A1: B is_a_component_of (L~f)` and
A2: not B is bounded;
A3: ex B1 being Subset of (TOP-REAL 2) | (L~f)` st B1 = B & B1
  is a_component by A1,CONNSP_1:def 6;
  consider r1 being Real such that
A4: for q being Point of TOP-REAL 2 st q in L~f holds |.q.|<r1 by Th21;
  consider q4 being Point of TOP-REAL 2 such that
A5: q4 in B and
A6: |.q4.|>=r1 by A2,Th21;
A7: now
    assume q4 in {q where q is Point of TOP-REAL 2: (|.q.|) <r1};
    then ex q being Point of TOP-REAL 2 st q=q4 & (|.q.|) <r1;
    hence contradiction by A6;
  end;
  reconsider P=(REAL 2)\ {q where q is Point of TOP-REAL 2: (|.q.|) < r1 } as
  Subset of TOP-REAL 2 by EUCLID:22;
  P c= (the carrier of TOP-REAL 2)\(L~f)
  proof
    let z be object;
    assume
A8: z in P;
    now
      assume
A9:   z in L~f;
      then reconsider q3=z as Point of TOP-REAL 2;
A10:  not q3 in {q where q is Point of TOP-REAL 2: (|.q.|) < r1 } by A8,
XBOOLE_0:def 5;
      |.q3.|<r1 by A4,A9;
      hence contradiction by A10;
    end;
    hence thesis by A8,XBOOLE_0:def 5;
  end;
  then
A11: P /\ ((the carrier of TOP-REAL 2)\(L~f))=P by XBOOLE_1:28;
  then
A12: Down(P,(L~f)`) is connected by Th40,CONNSP_1:46;
  not LeftComp f is bounded by Th74;
  then consider q3 being Point of TOP-REAL 2 such that
A13: q3 in LeftComp f and
A14: |.q3.|>=r1 by Th21;
A15: now
    assume q3 in {q where q is Point of TOP-REAL 2: (|.q.|) <r1};
    then ex q being Point of TOP-REAL 2 st q=q3 & (|.q.|) <r1;
    hence contradiction by A14;
  end;
  q4 in the carrier of TOP-REAL 2;
  then q4 in REAL 2 by EUCLID:22;
  then q4 in P by A7,XBOOLE_0:def 5;
  then
A16: B meets P by A5,XBOOLE_0:3;
  LeftComp f is_a_component_of (L~f)` by GOBOARD9:def 1;
  then consider L1 being Subset of (TOP-REAL 2) | (L~f)` such that
A17: L1 = LeftComp f and
A18: L1 is a_component by CONNSP_1:def 6;
  q3 in the carrier of TOP-REAL 2;
  then q3 in REAL 2 by EUCLID:22;
  then q3 in P by A15,XBOOLE_0:def 5;
  then L1 meets P by A17,A13,XBOOLE_0:3;
  hence thesis by A3,A17,A18,A11,A12,A16,Th76;
end;
