reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th94:
  for sn being Real, K0,B0 being Subset of TOP-REAL 2,f being
Function of (TOP-REAL 2)|K0,(TOP-REAL 2)|B0 st -1<sn & sn<1 & f=(sn-FanMorphE)|
  K0 & B0=NonZero TOP-REAL 2 & K0={p: p`1<=0 & p<>0.TOP-REAL 2} holds f is
  continuous
proof
  let sn be Real,K0,B0 be Subset of TOP-REAL 2,
f be Function of (TOP-REAL 2)|
  K0,(TOP-REAL 2)|B0;
  set cn=sqrt(1-sn^2);
  set p0=|[-cn,-sn]|;
  assume
A1: -1<sn & sn<1 & f=(sn-FanMorphE)|K0 & B0=NonZero TOP-REAL 2 & K0={p:
  p`1<=0 & p<>0.TOP-REAL 2};
  then sn^2<1^2 by SQUARE_1:50;
  then 1-sn^2>0 by XREAL_1:50;
  then --cn>0 by SQUARE_1:25;
  then
A2: p0`1=-cn & -cn<0 by EUCLID:52;
  then p0 in K0 by A1,JGRAPH_2:3;
  then reconsider K1=K0 as non empty Subset of TOP-REAL 2;
  not p0 in {0.TOP-REAL 2} by A2,JGRAPH_2:3,TARSKI:def 1;
  then reconsider D=B0 as non empty Subset of TOP-REAL 2 by A1,XBOOLE_0:def 5;
A3: K1 c= D
  proof
    let x be object;
    assume x in K1;
    then consider p2 being Point of TOP-REAL 2 such that
A4: p2=x and
    p2`1<=0 and
A5: p2<>0.TOP-REAL 2 by A1;
    not p2 in {0.TOP-REAL 2} by A5,TARSKI:def 1;
    hence thesis by A1,A4,XBOOLE_0:def 5;
  end;
  for p being Point of (TOP-REAL 2)|K1,V being Subset of (TOP-REAL 2)|D
st f.p in V & V is open holds ex W being Subset of (TOP-REAL 2)|K1 st p in W &
  W is open & f.:W c= V
  proof
    let p be Point of (TOP-REAL 2)|K1,V be Subset of (TOP-REAL 2)|D;
    assume that
A6: f.p in V and
A7: V is open;
    consider V2 being Subset of TOP-REAL 2 such that
A8: V2 is open and
A9: V2 /\ [#]((TOP-REAL 2)|D)=V by A7,TOPS_2:24;
    reconsider W2=V2 /\ [#]((TOP-REAL 2)|K1) as Subset of (TOP-REAL 2)| K1;
A10: [#]((TOP-REAL 2)|K1)=K1 by PRE_TOPC:def 5;
    then
A11: f.p=(sn-FanMorphE).p by A1,FUNCT_1:49;
A12: f.:W2 c= V
    proof
      let y be object;
      assume y in f.:W2;
      then consider x being object such that
A13:  x in dom f and
A14:  x in W2 and
A15:  y=f.x by FUNCT_1:def 6;
      f is Function of (TOP-REAL 2)|K1, (TOP-REAL 2)|D;
      then dom f= K1 by A10,FUNCT_2:def 1;
      then consider p4 being Point of TOP-REAL 2 such that
A16:  x=p4 and
A17:  p4`1<=0 and
      p4<>0.TOP-REAL 2 by A1,A13;
A18:  p4 in V2 by A14,A16,XBOOLE_0:def 4;
      p4 in [#]((TOP-REAL 2)|K1) by A13,A16;
      then p4 in D by A3,A10;
      then
A19:  p4 in [#]((TOP-REAL 2)|D) by PRE_TOPC:def 5;
      f.p4=(sn-FanMorphE).p4 by A1,A10,A13,A16,FUNCT_1:49
        .=p4 by A17,Th82;
      hence thesis by A9,A15,A16,A18,A19,XBOOLE_0:def 4;
    end;
    p in the carrier of (TOP-REAL 2)|K1;
    then consider q being Point of TOP-REAL 2 such that
A20: q=p and
A21: q`1<=0 and
    q <>0.TOP-REAL 2 by A1,A10;
    (sn-FanMorphE).q=q by A21,Th82;
    then p in V2 by A6,A9,A11,A20,XBOOLE_0:def 4;
    then
A22: p in W2 by XBOOLE_0:def 4;
    W2 is open by A8,TOPS_2:24;
    hence thesis by A22,A12;
  end;
  hence thesis by JGRAPH_2:10;
end;
