reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;
reserve D for non vertical non horizontal non empty compact Subset of TOP-REAL
  2;

theorem Th78:
  RightComp SpStSeq D c= BDD (L~SpStSeq D) & RightComp SpStSeq D is bounded
proof
  set f=SpStSeq D;
  set A=L~SpStSeq D;
A1: RightComp f is_a_component_of A`by GOBOARD9:def 2;
A2: now
A3: LeftComp f misses RightComp f by SPRECT_1:88;
    assume not (RightComp f) is bounded;
    hence contradiction by A1,A3,Th77;
  end;
  then
A4: RightComp f is_inside_component_of A by A1;
  RightComp f c= union{B where B is Subset of TOP-REAL 2: B
  is_inside_component_of A}
  proof
    let x be object;
    assume
A5: x in RightComp f;
    RightComp f in {B where B is Subset of TOP-REAL 2: B
    is_inside_component_of A} by A4;
    hence thesis by A5,TARSKI:def 4;
  end;
  hence RightComp f c= BDD (L~SpStSeq D);
  thus thesis by A2;
end;
