reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;
reserve D for non vertical non horizontal non empty compact Subset of TOP-REAL
  2;

theorem Th79:
  LeftComp SpStSeq D = UBD (L~SpStSeq D) & RightComp SpStSeq D =
  BDD (L~SpStSeq D)
proof
  set f=SpStSeq D;
A1: (L~f)`=LeftComp f \/ RightComp f by GOBRD12:10;
A2: LeftComp f c= UBD (L~SpStSeq D) by Th75;
A3: RightComp f c= BDD (L~SpStSeq D) by Th78;
A4: now
    assume not LeftComp f = UBD (L~SpStSeq D);
    then not UBD (L~SpStSeq D) c= LeftComp f by A2;
    then consider z being object such that
A5: z in UBD (L~SpStSeq D) and
A6: not z in LeftComp f;
    UBD (L~f) c= (L~f)` by Th17;
    then z in LeftComp f or z in RightComp f by A1,A5,XBOOLE_0:def 3;
    then (BDD L~f) meets (UBD L~f) by A3,A5,A6,XBOOLE_0:3;
    hence contradiction by Th15;
  end;
  now
    assume not RightComp f = BDD (L~SpStSeq D);
    then not BDD (L~SpStSeq D) c= RightComp f by A3;
    then consider z being object such that
A7: z in BDD (L~SpStSeq D) and
A8: not z in RightComp f;
    BDD (L~f) c= (L~f)` by Th16;
    then z in LeftComp f or z in RightComp f by A1,A7,XBOOLE_0:def 3;
    then (BDD L~f) meets (UBD L~f) by A2,A7,A8,XBOOLE_0:3;
    hence contradiction by Th15;
  end;
  hence thesis by A4;
end;
