reserve k,n for Nat,
  x,y,z,y1,y2 for object,X,Y for set,
  f,g for Function;
reserve p,q,r,s,t for XFinSequence;
reserve D for set;
reserve i for Nat;
reserve m for Nat,
        D for non empty set;
reserve l for Nat;
reserve M for Nat;
reserve m,n for Nat;
reserve x1,x2,x3,x4 for object;
reserve e,u for object;

theorem Th15:
  for D being set, p being FinSequence of D holds rng p = rng FS2XFS p
proof
  let D be set, p be FinSequence of D;
  for y being object
  holds y in rng FS2XFS p iff ex x being object st x in dom p & p.x = y
  proof
    let y be object;
    thus y in rng FS2XFS p implies ex x being object st x in dom p & p.x = y
    proof
      assume y in rng FS2XFS p;
      then consider n being object such that
        A1: n in dom FS2XFS p & (FS2XFS p).n = y by FUNCT_1:def 3;:::AFINSQ_2:3;
      reconsider n as Nat by A1;
      take n+1;
      thus n+1 in dom p by A1, Th13;
      n < len FS2XFS p by A1, Lm1;
      then n < len p by Def8;
      hence p.(n+1) = y by A1, Def8;
    end;
    given x being object such that
      A2: x in dom p & p.x = y;
    reconsider n1 = x as Nat by A2;
    A3: 1 <= n1 & n1 <= len p by A2, FINSEQ_3:25;
    then reconsider n = n1-1 as Nat by Th0;
    n < len p - 0 by A3, XREAL_1:15;
    then A4: p.(n+1) = (FS2XFS p).n by Def8;
    n+1 in dom p by A2;
    then n in dom FS2XFS p by Th13;
    hence thesis by A2, A4, FUNCT_1:3;
  end;
  hence thesis by FUNCT_1:def 3;
end;
