reserve A,B for Ordinal,
  K,M,N for Cardinal,
  x,x1,x2,y,y1,y2,z,u for object,X,Y,Z,X1,X2, Y1,Y2 for set,
  f,g for Function;
reserve m,n for Nat;
reserve x1,x2,x3,x4,x5,x6,x7,x8 for object;
reserve A,B,C for Ordinal,
  K,L,M,N for Cardinal,
  x,y,y1,y2,z,u for object,X,Y,Z,Z1,Z2 for set,
  n for Nat,
  f,f1,g,h for Function,
  Q,R for Relation;
reserve n,k for Nat;

theorem Th95:
  K in L & M in N implies K+`M in L+`N & M+`K in L+`N
proof
A1: for K,L,M,N st K in L & M in N & L c= N holds K+`M in L+`N
  proof
    let K,L,M,N such that
A2: K in L and
A3: M in N and
A4: L c= N;
   per cases;
   suppose
A5:   N is finite;
      then reconsider N as finite Cardinal;
      reconsider L,M,K as finite Cardinal by A2,A3,A4,A5,CARD_3:92;
A6:   card Segm K = K;
A7:   card Segm L = L;
A8:   card Segm M = M;
A9:  card Segm N = N;
A10:  K+`M = card Segm(card K + card M) by Th37;
A11:  L+`N = card Segm(card L + card N) by Th37;
A12:  card K < card L by A2,A6,A7,NAT_1:41;
      card M < card N by A3,A8,A9,NAT_1:41;
      then card K + card M < card L + card N by A12,XREAL_1:8;
      hence thesis by A10,A11,NAT_1:41;
    end;
   suppose
A13:  N is not finite;
      then
A14:  L+`N = N by A4,Th75;
A15:  omega c= N by A13,CARD_3:85;
      K c= M & (M is finite or M is not finite) or
      M c= K & (K is finite or K is not finite);
      then
A16:  K is finite & M is finite or K+`M = M or K+`M = K & K in N
      by A2,A4,Th75;
      K is finite & M is finite implies thesis by A14,A15,CARD_1:61;
      hence thesis by A3,A4,A13,A16,Th75;
    end;
  end;
  L c= N or N c= L;
  hence thesis by A1;
end;
