reserve U for Universe;
reserve x for Element of U;
reserve U1,U2 for Universe;

theorem Th98:
  for C being U-locally_small Category st the carrier of C is U-set holds
  union the set of all Hom(a,b) where a,b is Object of C is Element of U
  proof
    let C be U-locally_small Category;
    assume
A1: the carrier of C is U-set;
A2: now
      let a be Object of C;
      reconsider cC = the carrier of C as non empty set;
      reconsider c9C = the carrier' of C as non empty set;
      defpred P[Object of C,Element of U] means Hom(a,$1) = $2;
A3:   now
        let x be Element of the carrier of C;
        Hom(a,x) is U-set by Def36;
        hence ex y be Element of U st P[x,y];
      end;
      ex f be Function of the carrier of C,U st
      for x be Element of the carrier of C holds P[x,f.x]
        from FUNCT_2:sch 3(A3);
      hence ex f being Function of the carrier of C,U st
        for x be Object of C holds f.x = Hom(a,x);
    end;
A4: now
      let a be Object of C;
      consider f be Function of the carrier of C,U such that
A5:   for x be Object of C holds f.x = Hom(a,x) by A2;
A6:   now
        now
          let t be object;assume t in rng f;
          then consider u be object such that
A7:       u in the carrier of C and
A8:       t = f.u by FUNCT_2:11;
          reconsider u as Object of C by A7;
          t = Hom(a,u) by A8,A5;
          hence t in  the set of all Hom(a,b) where b is Object of C;
        end;
        hence rng f c= the set of all Hom(a,b) where b is Object of C;
        now
          let t be object;
          assume t in the set of all Hom(a,b) where b is Object of C;
          then consider b be Object of C such that
A9:       t = Hom(a,b);
          t = f.b by A5,A9;
          hence t in rng f by FUNCT_2:4;
        end;
        hence the set of all Hom(a,b) where b is Object of C c= rng f;
      end;
      then
A10:  rng f = the set of all Hom(a,b) where b is Object of C;
      now
        let t be object;
        assume t in the set of all Hom(a,b) where b is Object of C;
        then consider b be Object of C such that
A11:    t = Hom(a,b);
        Hom(a,b) is U-set by Def36;
        hence t in U by A11;
      end;
      then
A12:  rng f c= U by A6;
      dom f = the carrier of C by PARTFUN1:def 2;
      hence union the set of all Hom(a,b) where b is Object of C in U
        by A1,A10,A12,CLASSES4:5;
    end;
    defpred P[Object of C,Element of U] means
    union the set of all Hom($1,b) where b is Object of C = $2;
A13: now
      let x be Element of the carrier of C;
      reconsider y = union the set of all Hom(x,b) where
        b is Object of C as Element of U by A4;
      union the set of all Hom(x,b) where b is Object of C = y;
      hence ex y be Element of U st P[x,y];
    end;
    consider f being Function of the carrier of C,U such that
A14: for x be Element of the carrier of C holds P[x,f.x]
      from FUNCT_2:sch 3(A13);
A15: for x be object st x in dom f holds f.x in U
    proof
      let x be object;
      assume x in dom f;
      then reconsider x9 = x as Object of C by FUNCT_2:def 1;
      f.x9 in U;
      hence thesis;
    end;
    now
      let x be object;
      assume x in rng f;
      then consider y be object such that
A16:  y in the carrier of C and
A17:  x = f.y by FUNCT_2:11;
      dom f = the carrier of C by PARTFUN1:def 2;
      hence x in U by A17,A16,A15;
    end;
    then
A18: rng f c= U;
A19: dom f in U by A1,PARTFUN1:def 2;
A20: now
      let x be object; assume x in rng f;
      then consider y be object such that
A21:  y in the carrier of C and
A22:  x = f.y by FUNCT_2:11;
      reconsider y as Element of the carrier of C by A21;
      P[y,f.y] by A14;
      hence ex y be Element of the carrier of C st
        union the set of all Hom(y,b) where b is Object of C = x by A22;
    end;
    now
      now
        let x be object;
        assume x in union rng f;
        then consider y be set such that
A23:    x in y in rng f by TARSKI:def 4;
        consider z be Element of the carrier of C such that
A24:    y = union the set of all Hom(z,b) where b is Object of C by A23,A20;
        reconsider z as Object of C;
        consider t be set such that
A25:    x in t in the set of all Hom(z,b) where b is Object of C
          by A23,A24,TARSKI:def 4;
        consider b0 be Object of C such that
A26:    t = Hom(z,b0) by A25;
        x in Hom(z,b0) in the set of all Hom(a,b) where a,b is Object of C
          by A25,A26;
        hence x in union the set of all Hom(a,b) where a,b is Object of C
          by TARSKI:def 4;
      end;
      hence union rng f c= union the set of all Hom(a,b)
        where a,b is Object of C;
      now
        let x be object;
        assume x in union the set of all Hom(a,b) where a,b is Object of C;
        then consider y be set such that
A27:     x in y in the set of all Hom(a,b) where a,b is Object of C
          by TARSKI:def 4;
        consider a9,b9 be Object of C such that
A28:    y = Hom(a9,b9) by A27;
        reconsider a9 as Element of the carrier of C;
        y in the set of all Hom(a9,b) where b is Object of C by A28;
        then
A29:     x in union the set of all Hom(a9,b) where b is Object of C
          by A27,TARSKI:def 4;
A30:    union the set of all Hom(a9,b) where b is Object of C = f.a9 by A14;
        f.a9 in rng f by FUNCT_2:4;
        hence x in union rng f by A30,A29,TARSKI:def 4;
      end;
      hence union the set of all Hom(a,b)
        where a,b is Object of C c= union rng f;
    end;
    then union rng f = union the set of all Hom(a,b) where a,b is Object of C;
    hence thesis by A19,A18,CLASSES4:5;
  end;
