
theorem Th96:
  for p1,p2,p3,p4 being Point of TOP-REAL 2, a,b,c,d being Real
, f,g being Function of I[01],TOP-REAL 2 st a<b & c < d & p1`1=a & p2`2=d
& p3`1=b & p4`2= c & c <=p1`2 & p1`2<=d & a<=p2`1 & p2`1<=b & c <=p3`2 & p3`2<=
  d & a <p4`1 & p4`1<=b & f.0=p1 & f.1=p3 & g.0=p2 & g.1=p4 & f is continuous
one-to-one & g is continuous one-to-one & rng f c= closed_inside_of_rectangle(a
,b,c,d) & rng g c= closed_inside_of_rectangle(a,b,c,d) holds rng f meets rng g
proof
  reconsider O=0,I=1 as Point of I[01] by BORSUK_1:40,XXREAL_1:1;
  let p1,p2,p3,p4 be Point of TOP-REAL 2, a,b,c,d be Real, f,g be
  Function of I[01],TOP-REAL 2;
  assume that
A1: a<b and
A2: c < d and
A3: p1`1=a and
A4: p2`2=d and
A5: p3`1=b and
A6: p4`2= c and
A7: c <=p1`2 and
A8: p1`2<=d and
A9: a<=p2`1 and
A10: p2`1<=b and
A11: c <=p3`2 and
A12: p3`2<=d and
A13: a <p4`1 and
A14: p4`1<=b and
A15: f.0=p1 and
A16: f.1=p3 and
A17: g.0=p2 and
A18: g.1=p4 and
A19: f is continuous one-to-one and
A20: g is continuous one-to-one and
A21: rng f c= closed_inside_of_rectangle(a,b,c,d) and
A22: rng g c= closed_inside_of_rectangle(a,b,c,d);
  set A=2/(b-a), B=-(b+a)/(b-a), C = 2/(d-c), D=-(d+c)/(d-c);
  set h=AffineMap(A,B,C,D);
  reconsider g2= h*g as Function of I[01],TOP-REAL 2;
A23: -1<((g2).I)`1 by A1,A13,A14,A18,Th64;
  reconsider f2= h*f as Function of I[01],TOP-REAL 2;
A24: -1 <=((f2).O)`2 by A2,A7,A8,A15,Th60;
A25: ((f2).O)`2<=1 by A2,A7,A8,A15,Th60;
A26: f2 is continuous one-to-one by A1,A2,A19,Th53;
A27: -1<=((f2).I)`2 by A2,A11,A12,A16,Th60;
A28: ((f2).O)`1= -1 by A1,A3,A15,Th54;
A29: rng (f2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A21,Th52;
  set x = the Element of rng f2 /\ rng g2;
  d-c >0 by A2,XREAL_1:50;
  then
A30: C >0 by XREAL_1:139;
A31: (g.I)`2= c by A6,A18;
  then
A32: ((g2).O)`1<=1 by A1,A9,A10,A13,A14,A17,A18,Th64;
A33: ((g2).I)`1<=1 by A1,A13,A14,A18,Th64;
A34: g2 is continuous one-to-one by A1,A2,A20,Th53;
A35: rng (g2) c= closed_inside_of_rectangle(-1,1,-1,1) by A1,A2,A22,Th52;
A36: ((g2).I)`2= -1 by A2,A6,A18,Th57;
A37: ((g2).O)`2= 1 by A2,A4,A17,Th55;
A38: ((f2).I)`2<=1 by A2,A11,A12,A16,Th60;
A39: ((f2).I)`1= 1 by A1,A5,A16,Th56;
  -1 <=((g2).O)`1 by A1,A9,A10,A13,A14,A17,A18,A31,Th64;
  then rng f2 meets rng g2 by A26,A28,A39,A24,A25,A27,A38,A29,A34,A37,A36,A32
,A23,A33,A35,Th28,JGRAPH_6:79;
  then
A40: rng f2 /\ rng g2 <>{} by XBOOLE_0:def 7;
  then x in rng f2 by XBOOLE_0:def 4;
  then consider z1 being object such that
A41: z1 in dom f2 and
A42: x=f2.z1 by FUNCT_1:def 3;
A43: dom f=the carrier of I[01] by FUNCT_2:def 1;
  then
A44: f.z1 in rng f by A41,FUNCT_1:def 3;
  b-a>0 by A1,XREAL_1:50;
  then A >0 by XREAL_1:139;
  then h is being_homeomorphism by A30,Th51;
  then
A45: h is one-to-one by TOPS_2:def 5;
  f.z1 in the carrier of TOP-REAL 2 by A41,FUNCT_2:5;
  then
A46: f.z1 in dom h by FUNCT_2:def 1;
  x in rng g2 by A40,XBOOLE_0:def 4;
  then consider z2 being object such that
A47: z2 in dom g2 and
A48: x=g2.z2 by FUNCT_1:def 3;
A49: dom g=the carrier of I[01] by FUNCT_2:def 1;
  then
A50: g.z2 in rng g by A47,FUNCT_1:def 3;
A51: x=h.(g.z2) by A49,A47,A48,FUNCT_1:13;
  g.z2 in the carrier of TOP-REAL 2 by A47,FUNCT_2:5;
  then
A52: g.z2 in dom h by FUNCT_2:def 1;
  x=h.(f.z1) by A43,A41,A42,FUNCT_1:13;
  then f.z1=g.z2 by A51,A46,A52,A45,FUNCT_1:def 4;
  hence thesis by A44,A50,XBOOLE_0:3;
end;
