reserve A,B for Ordinal,
        o for object,
        x,y,z for Surreal,
        n for Nat,
        r,r1,r2 for Real;

theorem Th96:
  for r be Sequence of REAL, y be Surreal-Sequence
    for s be uSurreal-Sequence
      for A be Ordinal st s,y,r simplest_up_to A & A c= succ dom y holds
  s|A is one-to-one
proof
  let r be Sequence of REAL, y be Surreal-Sequence;
  let s be uSurreal-Sequence;
  let A be Ordinal such that
A1: s,y,r simplest_up_to A & A c= succ dom y;
A2: for a,b be Ordinal st a in b in dom (s|A) holds (s|A).a <> (s|A).b
  proof
    let a,b be Ordinal such that
A3: a in b in dom (s|A);
A4: b in A & b in dom s by A3,RELAT_1:57;
    then a in dom s by A3,ORDINAL1:10;
    then s.b in rng s & s.a in rng s by A4,FUNCT_1:def 3;
    then reconsider sb=s.b,sa=s.a as uSurreal by SURREALO:def 12;
A5: sa = (s|A).a & sb = (s|A).b by A3,FUNCT_1:47,ORDINAL1:10;
A6: succ a c= b by A3,ORDINAL1:21;
    s,y,r simplest_on_position b by A1,A3;
    then sb in_meets_terms s,y,r,b;
    then
A7: sb in_meets_terms s,y,r,succ a by A6;
    b c= dom y by A1,A4,ORDINAL1:22;
    then y.a in rng y by A3,FUNCT_1:def 3;
    then reconsider ya=y.a as Surreal by SURREAL0:def 16;
    sb is (sa,ya,r.a)_term by A7,ORDINAL1:6;
    then
A8: not sb + - sa ==0_No;
    not sb == sa
    proof
      assume sb == sa;
      then sb +- sa == sa - sa == 0_No by SURREALR:43,39;
      hence thesis by A8,SURREALO:4;
    end;
    hence thesis by A5;
  end;
  for x1,x2 be object st x1 in dom (s|A) & x2 in dom (s|A) & (s|A).x1 =(s|A).x2
  holds x1=x2
  proof
    let x1,x2 be object such that
A9: x1 in dom (s|A) & x2 in dom (s|A) & (s|A).x1 =(s|A).x2;
    reconsider x1,x2 as Ordinal by A9;
    not x1 in x2 & not x2 in x1 by A9,A2;
    hence thesis by ORDINAL1:14;
  end;
  hence thesis by FUNCT_1:def 4;
end;
