reserve
  S for (4,1) integer bool-correct non empty non void BoolSignature,
  X for non-empty ManySortedSet of the carrier of S,
  T for vf-free integer all_vars_including inheriting_operations free_in_itself
  (X,S)-terms VarMSAlgebra over S,
  C for (4,1) integer bool-correct non-empty image of T,
  G for basic GeneratorSystem over S,X,T,
  A for IfWhileAlgebra of the generators of G,
  I for integer SortSymbol of S,
  x,y,z,m for pure (Element of (the generators of G).I),
  b for pure (Element of (the generators of G).the bool-sort of S),
  t,t1,t2 for Element of T,I,
  P for Algorithm of A,
  s,s1,s2 for Element of C-States(the generators of G);
reserve
  f for ExecutionFunction of A, C-States(the generators of G),
  (\falseC)-States(the generators of G, b);
reserve u for ManySortedFunction of FreeGen T, the Sorts of C;
reserve
  S for 1-1-connectives (4,1) integer (11,1,1)-array 11 array-correct
  bool-correct non empty non void BoolSignature,
  X for non-empty ManySortedSet of the carrier of S,
  T for vf-free all_vars_including inheriting_operations free_in_itself
  (X,S)-terms integer-array non-empty VarMSAlgebra over S,
  C for (11,1,1)-array (4,1) integer bool-correct non-empty image of T,
  G for basic GeneratorSystem over S,X,T,
  A for IfWhileAlgebra of the generators of G,
  I for integer SortSymbol of S,
  x,y,m,i for pure (Element of (the generators of G).I),
  M,N for pure (Element of (the generators of G).the_array_sort_of S),
  b for pure (Element of (the generators of G).the bool-sort of S),
  s,s1 for (Element of C-States(the generators of G));
reserve u for ManySortedFunction of FreeGen T, the Sorts of C;
reserve i1,i2 for pure Element of (the generators of G).I;

theorem Th97:
  for X being countable non-empty ManySortedSet of the carrier of S
  for T being vf-free all_vars_including inheriting_operations free_in_itself
  (X,S)-terms integer-array non-empty VarMSAlgebra over S
  for G being basic GeneratorSystem over S,X,T
  for M being pure Element of (the generators of G).the_array_sort_of S
  for i,x being pure Element of (the generators of G).I holds
  @M.@i <> x
  proof
    let X be countable non-empty ManySortedSet of the carrier of S;
    let T be vf-free all_vars_including inheriting_operations free_in_itself
    (X,S)-terms integer-array non-empty VarMSAlgebra over S;
    let G be basic GeneratorSystem over S,X,T;
    let M be pure Element of (the generators of G).the_array_sort_of S;
    let i,x be pure Element of (the generators of G).I;
    set C = the (11,1,1)-array (4,1) integer bool-correct non-empty image of T;
    set ST = C-States the generators of G;
    assume
A1: @M.@i = x;
    set q = the ManySortedFunction of FreeGen T, the Sorts of C;
    set g = q+*(I,x,0)+*(the_array_sort_of S,M,<%1%>)+*(I,i,0);
    set a = the_array_sort_of S;
    consider h being ManySortedFunction of T,C such that
A2: h is_homomorphism T,C & h||FreeGen T = g by MSAFREE4:def 12;
    reconsider s = h||the generators of G as Element of ST
    by A2,AOFA_A00:def 19;
A3: the_array_sort_of S <> I by Th73;
A4: @M value_at(C,s) = s.(the_array_sort_of S).M &
    @i value_at(C,s) = s.I.i &
    @M.@i value_at(C,s) = (@M value_at(C,s)).(@i value_at(C,s)) by Th79,Th61;
A5: i in (FreeGen T).I & x in (FreeGen T).I & M in (FreeGen T).a by Def4;
A6: dom ((q+*(I,x,0)+*(a,M,<%1%>)).I) = (FreeGen T).I &
    0 in INT & INT = (the Sorts of C).I
    by INT_1:def 2,AOFA_A00:55,FUNCT_2:def 1;
    ((h.I)|((the generators of G).I)).i = h.I.i by FUNCT_1:49;
    then
A7: s.I.i = h.I.i by MSAFREE:def 1
    .= ((h.I)|((FreeGen T).I)).i by Def4,FUNCT_1:49
    .= g.I.i by A2,MSAFREE:def 1
    .= (((q+*(I,x,0)+*(a,M,<%1%>)).I)+*(i,0)).i by A5,A6,AOFA_A00:def 2
    .= 0 by Def4,A6,FUNCT_7:31;
    reconsider 01 = 1 as Element of INT by INT_1:def 2;
A8: <%01%> in INT^omega & (the Sorts of C).a = INT^omega &
    dom ((q+*(I,x,0)).a) = (FreeGen T).a & dom (q.I) = (FreeGen T).I &
    dom ((q+*(I,x,0)+*(a,M,<%1%>)).a) = (FreeGen T).a
    by Th74,AFINSQ_1:def 7,FUNCT_2:def 1;
A9: s.a.M = ((h.a)|((the generators of G).a)).M by MSAFREE:def 1
    .= h.a.M by FUNCT_1:49
    .= ((h.a)|((FreeGen T).a)).M by Def4,FUNCT_1:49
    .= g.a.M by A2,MSAFREE:def 1
    .= (q+*(I,x,0)+*(a,M,<%1%>)).a.M by A5,A6,A3,AOFA_A00:def 2
    .= (q+*(I,x,0)).a+*(M,<%1%>).M by A8,A5,AOFA_A00:def 2
    .= <%1%> by Def4,A8,FUNCT_7:31;
    0 < len(s.a.M) by A9,AFINSQ_1:34;
    then 0 in dom(s.a.M) by AFINSQ_1:86;
    then @x value_at(C,s) = s.a.M.(s.I.i) by A1,A4,Th74,A7;
    then
A10: s.I.x = <%1%>.(s.I.i) by A9,Th61
    .= 1 by A7;
    s.I.x = ((h.I)|((the generators of G).I)).x by MSAFREE:def 1
    .= h.I.x by FUNCT_1:49
    .= ((h.I)|((FreeGen T).I)).x by Def4,FUNCT_1:49
    .= g.I.x by A2,MSAFREE:def 1
    .= ((q+*(I,x,0)+*(a,M,<%1%>)).I+*(i,0)).x by A5,A6,AOFA_A00:def 2
    .= (q+*(I,x,0)+*(a,M,<%1%>)).I.x by A7,A10,FUNCT_7:32
    .= (q+*(I,x,0)).I.x by A3,A5,A8,AOFA_A00:def 2
    .= ((q.I)+*(x,0)).x by A5,A6,AOFA_A00:def 2
    .= 0 by Def4,A8,FUNCT_7:31;
    hence contradiction by A10;
  end;
